主页 / coding / 问题 / 79108104
Accepted
PTQuoc
Asked: 2024-10-21 05:40:50 +0800 CST

Excel IFS 函数

  • 772

我使用 Excel IFS 函数添加 *

其工作功能为：

=IF(G5="","",FIXED(G5,1)&IFS(ABS(G6)>=2.575,"***",ABS(G6)>=1.96,"**",ABS(G6)>=1.645,"*",ABS(G6)<1.645,""))

因为我认为 ABS(G6)<1.645 是多余的，所以我决定放弃它

=IF(G5="","",FIXED(G5,1)&IFS(ABS(G6)>=2.575,"***",ABS(G6)>=1.96,"**",ABS(G6)>=1.645,"*"))

但公式遇到问题返回#N/A

我希望有人能为我解释为什么删除部分会导致这个问题？

excel

2 个回答

  1. Best Answer

    您需要为 IFS 提供“else”分支：

    =IF(G5="",
  "",
  FIXED(G5,1)&IFS(
    ABS(G6)>=2.575,"***",
    ABS(G6)>=1.96,"**",
    ABS(G6)>=1.645,"*",
    TRUE,""
  )
)

    阅读IFS函数中的备注：

    要指定默认结果，请为最后一个 logical_test 参数输入 TRUE。如果其他条件均不满足，则将返回相应的值。

    • 如果提供了 logical_test 参数而没有相应的 value_if_true，则此函数会显示“您为此函数输入的参数太少”错误消息。
    • 如果对 logical_test 参数进行求值并将其解析为除 TRUE 或 FALSE 之外的值，则此函数将返回“#VALUE!”错误。
    • 如果未找到任何 TRUE 条件，此函数将返回“#N/A”错误。

    因此，您得到了“#N/A”，因为ABS(G6)<1.645列表中没有这样的条件。

    另外，您可以通过另一种方式抑制“#N/A”：

    =IF(G5="",
  "",
  FIXED(G5,1)&IFNA(
    IFS(
      ABS(G6)>=2.575,"***",
      ABS(G6)>=1.96,"**",
      ABS(G6)>=1.645,"*"
    ),
    ""
  )
)
    • 1

  2. 您的第一个公式是完整的，而第二个公式则不完整。 IFS 函数需要涵盖所有可能的情况，因此在第二个公式中，当 G6 值小于 1.65 时，它不知道该怎么做。 IFS 文档指出，您可以使用 ELSE 子句来处理指定范围未涵盖的任何值。查看此链接： https://www.ablebits.com/office-addins-blog/excel-ifs-function/

    • 0

相关问题