主页 / coding / 问题 / 79065256
Accepted
Michi
Asked: 2024-10-08 17:27:12 +0800 CST

根据单元格中的输入以灵活范围转置

  • 772
0 一个 乙 碳 德 埃 F 格
1 问题 1 第二季度 第三季度 Q4 产品 A
2 产品 A 500 900 100
3 产品 B 600 400 500
4 产品C 100 350 785 900
5 产品D 230 600 210 690 100
6 产品 E 310 900 480 125
7

在中Range G3:G6我想根据在中输入的行条件转置值Cell G1。
（注意：列出的产品Column A始终是唯一的。）

在此示例中，Row B2:E2forProduct A被转置并显示在 中Range G3:G6。

到目前为止我已经能够开发出这个公式：

=LET(
a,TRANSPOSE(B2:E2),
IFERROR(INDEX(FILTER(a,a<>0),SEQUENCE(4,,1)),""))

此公式有效。
但是，我不知道如何使Range B2:E2此公式中的 灵活，以便它根据 中的输入而变化Cell G1。

您是否知道如何修改它以使其发挥作用？

excel

6 个回答

  1. 另一个解决方案（更简单且性能更好）可以是：

    =TOCOL(XLOOKUP(G1,A2:A6,B2:E6),1)

    在此处输入图片描述

    • 3
  2. Best Answer

    将整个数据范围传递给data变量的另一种解决方案：

    =LET(data,A2:E6,
    Product,G1,
    TOCOL(FILTER(DROP(data,,1),CHOOSECOLS(data,1)=Product,"no result"),1))
    • 3 
  3. =LET(a,FILTER(B2:E6,A2:A6=G1),TRANSPOSE(FILTER(a,a<>0)))

    结果：

    在此处输入图片描述

    或者=TOCOL(FILTER(B2:E6,A2:A6=G1),3)如果你有 Excel 365

    • 2

  4. 另一个选择是使用FILTER()。

    =TOCOL(FILTER(B2:E6,A2:A6=G1),1)

    在此处输入图片描述

    • 1

  5. 因为每个问题都应该有一个过于复杂和过度设计的解决方案：

    =LET(
    product, J2,
    dataRange, B3:F7,
    productRow, XLOOKUP(product, INDEX(dataRange,,1), ROW(dataRange)-MIN(ROW(dataRange))+1),
    valuesRange, INDEX(dataRange, productRow, 2):INDEX(dataRange, productRow, 5),
    filteredValues, TRANSPOSE(FILTER(valuesRange, valuesRange<>0)),
    IFERROR(INDEX(filteredValues, SEQUENCE(4,,1)), "")
)

    在此处输入图片描述

    • 0

  6. 谢谢 Michal，但XMATCH感觉被冷落了 ;)

    =TOCOL(INDEX(B2:XLOOKUP(TRUE, E:E <> "", E:E, , , -1), 
XMATCH(G1, A2:XLOOKUP(TRUE, A:A <> "", A:A, , , -1)), ), 1)

    或者，由 rotabor 提供，（可容纳未来的条目start:XLOOKUP(TRUE, column <> "")：

    =TOCOL(XLOOKUP(G1,  
A2:XLOOKUP(TRUE, A:A <> "", A:A, , , -1),  
B2:XLOOKUP(TRUE, E:E <> "", E:E, , , -1)), 1)

    结果

    • 0

相关问题