主页 / coding / 问题 / 79053056
Accepted
Tom
Asked: 2024-10-04 14:26:16 +0800 CST

如何检测 Windows 10 与 Windows 11 以使用 Dwmapi.DwmSetWindowAttribute

  • 772

我有以下窗口圆角代码，仅适用于 Win11。现在我需要检测是否使用 Win10，以便以不同的方式对圆角进行处理。

我如何检查此代码是否确实使角变圆，以及/或者是否正在使用 Windows v11 或更新版本？

unit delphi_rounded_corners;

interface

uses
  Windows;

type
  TRoundedWindowCornerType = (RoundedCornerDefault, RoundedCornerOff, RoundedCornerOn, RoundedCornerSmall);

////////////////////////////////////////////////////////////////////////////
//
// Originally written by Ian Barker
//            https://github.com/checkdigits
//            https://about.me/IanBarker
//            [email protected]
//
// Based on an example in an answer during the RAD Studio 11 Launch Q & A
//
//
// Free software - use for any purpose including commercial use.
//
////////////////////////////////////////////////////////////////////////////
//
// Set or prevent Windows 11 from rounding the corners or your application
//
// Usage:
//         SetRoundedCorners(Self.Handle, RoundedCornerSmall);
//
////////////////////////////////////////////////////////////////////////////
///
procedure SetRoundedCorners(const TheHandle: HWND; const CornerType: TRoundedWindowCornerType);

implementation

uses
  Dwmapi;

const

  //
  // More information:
  //      https://docs.microsoft.com/en-us/windows/apps/desktop/modernize/apply-rounded-corners
  //      https://docs.microsoft.com/en-us/windows/win32/api/dwmapi/ne-dwmapi-dwmwindowattribute
  //      https://docs.microsoft.com/en-us/windows/win32/api/dwmapi/nf-dwmapi-dwmsetwindowattribute
  //

  DWMWCP_DEFAULT    = 0; // Let the system decide whether or not to round window corners
  DWMWCP_DONOTROUND = 1; // Never round window corners
  DWMWCP_ROUND      = 2; // Round the corners if appropriate
  DWMWCP_ROUNDSMALL = 3; // Round the corners if appropriate, with a small radius

  DWMWA_WINDOW_CORNER_PREFERENCE = 33; // [set] WINDOW_CORNER_PREFERENCE, Controls the policy that rounds top-level window corners

procedure SetRoundedCorners(const TheHandle: HWND; const CornerType: TRoundedWindowCornerType);
var
  DWM_WINDOW_CORNER_PREFERENCE: DWORD;
begin
  case CornerType of
    RoundedCornerOff:     DWM_WINDOW_CORNER_PREFERENCE := DWMWCP_DONOTROUND;
    RoundedCornerOn:      DWM_WINDOW_CORNER_PREFERENCE := DWMWCP_ROUND;
    RoundedCornerSmall:   DWM_WINDOW_CORNER_PREFERENCE := DWMWCP_ROUNDSMALL;
  else
    DWM_WINDOW_CORNER_PREFERENCE := DWMWCP_DEFAULT;
  end;

  // or simpler, since TRoundedWindowCornerType and
  // the DWM_WINDOW_CORNER_PREFERENCE enum have the
  // same numeric values:
  //
  // DWM_WINDOW_CORNER_PREFERENCE := Ord(CornerType);

  Dwmapi.DwmSetWindowAttribute(TheHandle, DWMWA_WINDOW_CORNER_PREFERENCE, @DWM_WINDOW_CORNER_PREFERENCE, sizeof(DWM_WINDOW_CORNER_PREFERENCE));
end;

end.
delphi

1 个回答

  1. Best Answer

    我如何检查此代码是否确实使角变圆，以及/或者是否正在使用 Windows v11 或更新版本？

    事实上，检查某个特定功能是否可用（或是否已成功使用）通常比针对特定 Windows 版本进行硬编码测试更好。

    在这种情况下，这很容易。当然，当你找到上面的代码时，你做的第一件事就是阅读该DwmSetWindowAttribute函数的文档：

    返回值

    类型：HRESULT

    如果函数成功，则返回S_OK。否则，返回HRESULT错误代码。

    因此，您只需检查结果。如果是S_OK，则您的角现在已变圆。否则，无法使角变圆，很可能是因为操作系统不支持圆角：

    例如（使用 Delphi 较新版本中附带的 DwmApi 单元）：

    procedure TForm1.FormClick(Sender: TObject);
begin
  var pref: DWORD := DWMWCP_ROUND;
  if not Succeeded(DwmSetWindowAttribute(Handle, DWMWA_WINDOW_CORNER_PREFERENCE, @pref, Sizeof(pref))) then
    ShowMessage('Failed to round the window''s corners.');
end;
    • 3

相关问题