主页 / coding / 问题 / 79022328
Accepted
kasia ka
Asked: 2024-09-25 18:18:52 +0800 CST

根据映射表更新列值

  • 772

我有下表

tab:([]exec_location_1:`PA1`DNS`DNS;quantity_s9:8 40 20;mf_quantity_s17:123 123 4;eq_quantity_s17:10 20 30)

我需要用基于以下映射的新列数量来更新它： orderQuantityMap:`NEW`XRM`PA1`PA3`PA4`PA5`XRT`XRB`MF1`DNS!(`quantity_s9`quantity_s9`quantity_s9`quantity_s9`quantity_s9`quantity_s9`quantity_s9`quantity_s9`mf_quantity_s17`eq_quantity_s17);

我猜测这需要作为功能更新来完成，因此尝试了以下操作：

![tab;();0b;(enlist `quantity)!enlist(orderQuantityMap;`exec_location_1)]

结果如下： 结果

我该如何更新它以便将列的实际值拉入数量列？

kdb

1 个回答

  1. Best Answer

    这是一个基本版本：

    q)update quantity:{x y}'[select quantity_s9, mf_quantity_s17, eq_quantity_s17 from tab;
                         orderQuantityMap exec_location_1] from tab
exec_location_1 quantity_s9 mf_quantity_s17 eq_quantity_s17 quantity
--------------------------------------------------------------------
PA1             8           123             10              8
DNS             40          123             20              20
DNS             20          4               30              30

    更多动态版本：

    q)update quantity:{x y}'[(distinct value orderQuantityMap)#tab;
                         orderQuantityMap exec_location_1] from tab
exec_location_1 quantity_s9 mf_quantity_s17 eq_quantity_s17 quantity
--------------------------------------------------------------------
PA1             8           123             10              8
DNS             40          123             20              20
DNS             20          4               30              30

    从技术上讲，您甚至不需要索引，只需使用@'：

    q)update quantity:tab@'orderQuantityMap exec_location_1 from tab
exec_location_1 quantity_s9 mf_quantity_s17 eq_quantity_s17 quantity
--------------------------------------------------------------------
PA1             8           123             10              8
DNS             40          123             20              20
DNS             20          4               30              30
    • 2

相关问题