主页 / coding / 问题 / 79019031
Accepted
Yuri
Asked: 2024-09-24 22:15:53 +0800 CST

Excel - 显示满足区分大小写条件的最高值的条目

  • 772

我正在使用的 Sheet 的简化示例

我有多个工作表，现在想添加一个统计工作表，该工作表仅显示每个工作表中比赛成绩最高的条目。这很容易。但是，我还想显示符合某些遗传条件的最高得分条目。这是让我感到麻烦的部分，因为它必须区分大小写，因为 A/A 与 a/a 有很大不同（这些是示例值）。

这就是我现在所拥有的：

=INDEX(Sheet1!$A$2:$A$100; MATCH(MAXIFS(Sheet1!$B$2:$B$100; Sheet1!$C$2:$C$100; "a/a"; Sheet1!$D$2:$D$100; "b/b"); Sheet1!$B$2:$B$100; 0))

它工作得很好，除了它不区分大小写，我不知道该怎么做才能使它区分大小写。结果应该是“TestCase4”，但由于这个原因，它变成了“TestCase1”。我已经尝试使用 CHAR() 来代替，但当然没有用。而且我无法让诸如 REGEXMATCH() 或 EXACT() 之类的东西在 MAXIFS 中工作。

我现在在遗传学旁边添加了一个新列，如果是 a/a 则记为 1，如果是 A/a 则记为 1.5，如果是 A/A 则记为 0，并在 MAXIFS 子句中检查这些列，但肯定有更好的解决方案吧？我还想让它在生物学上保持一定程度的准确性，所以仅仅改变字母是不行的。

谢谢任何提示！

excel-formula

2 个回答

  1. Best Answer

    如果你有 Excel 365，你可以使用FILTER

    =TAKE(SORT(FILTER(A2:C6,EXACT("a/a",C2:C6)),2,-1),1)

    在此处输入图片描述

    • 3

  2. 使用EXACT，替换MAXIFS为MAX & FILTER：

    =INDEX(
    Sheet1!$A$2:$A$100,
    MATCH(
        MAX(
            FILTER(
                Sheet1!$B$2:$B$100,
                EXACT(Sheet1!$C$2:$C$100, "a/a") *
                    EXACT(Sheet1!$D$2:$D$100, "b/b"),
                ""
            )
        ),
        Sheet1!$B$2:$B$100,
        0
    )
)

    结果

    如果有多个结果：

    =FILTER(
    Sheet1!$A$2:$A$100,
    Sheet1!$B$2:$B$100 =
        MAX(
            FILTER(
                Sheet1!$B$2:$B$100,
                EXACT(Sheet1!$C$2:$C$100, "a/a") *
                    EXACT(Sheet1!$D$2:$D$100, "b/b"),
                ""
            )
        )
)

    Google 表格更新

    Google Sheets 的FILTER语法与 Excel 略有不同：

    FILTER(范围，条件1，[条件2，...])

    [if_empty]因此，删除( )的第三个参数后，它就可以正常工作""：

    Google Sheet 结果

    • 1

相关问题