主页 / coding / 问题 / 79016423
Accepted
Gregg Rosenstein
Asked: 2024-09-24 06:03:43 +0800 CST

在 Excel 中查找最接近的日期

  • 772

我有一张包含两张表的电子表格，它们都有两列：ID和检查日期。

我想要：

  1. 查看第一张表中具有特定ID ( xxxxx) 和日期( )的行x/xx/xxxx。

  2. 然后，查看第二张工作表以查找具有相同ID的匹配项( xxxxx)。

  3. 在所有结果日期中，找出紧接在 之前的日期x/xx/xxxx。

excel-formula

3 个回答

  1. Best Answer

    您可以使用FILTER函数来查找其 ID 与 中的 ID 匹配的所有日期，Sheet2并且日期早于x/xx/xxxx。然后使用MAX找到最接近的匹配项：

    =MAX(FILTER(Sheet2!B:B, (Sheet2!A:A=A2)*(Sheet2!B:B<B2)))

    其中A2和B2是第一个选项卡中的 ID 和日期。

    如果没有匹配，IFERROR可以用以下方法来处理：

    =IFERROR(MAX(FILTER(Sheet2!B:B, (Sheet2!A:A=A2)*(Sheet2!B:B<B2))), "No Match")

    No Match如果没有匹配则返回。

    • 2

  2. 以下/此处参考：

        =LET(
w_,INDEX(C3:C8,MATCH(11111,B3:B8,0))+N("sht2, dates with same ID"),
x1_,SORT(FILTER(G3#,--ISNUMBER(SEARCH(11111,F3#))),,1)+N("necessary sort for type of match requested"),
y_,INDEX(x1_,MATCH(w_,x1_,1)) +N("voila!"),
y_)

    正确应用

    也许对我来说更感兴趣的是 Sht1 中多个日期与 11111 匹配的情况。可能吗？

    • 1

  3. 如果您有 Microsoft 365，您可以尝试以下操作：

    =LET(
    ids_1, A2:A5,
    dates_1, B2:B5,
    dates_2, Sheet2!B1:B17,
    ids_2, Sheet2!A1:A17,
    date_before, LAMBDA(id_1, date_1,
        TAKE(
            SORT(FILTER(dates_2, (ids_2 = id_1) * (dates_2 < date_1), ""), , -1),
            1
        )
    ),
    MAP(ids_1, dates_1, date_before)
)

    要自动包含最后一个非空白单元格，您可以像这样替换变量：

        ids_1, A2:XLOOKUP(TRUE, A:A <> "", A:A, , , -1),
    dates_1, B2:XLOOKUP(TRUE, B:B <> "", B:B, , , -1),
    ids_2, Sheet2!A1:XLOOKUP(TRUE, Sheet2!A:A <> "", Sheet2!A:A, , , -1),
    dates_2, Sheet2!B1:XLOOKUP(TRUE, Sheet2!B:B <> "", Sheet2!B:B, , , -1),

    结果

    • 0

相关问题