主页 / coding / 问题 / 78980231
Accepted
jtscheirer
Asked: 2024-09-13 08:15:55 +0800 CST

如何在 SAS 中按组计算日期之间的差异

  • 772

我有类似下面的数据，需要计算 Event_date 列中按 Subject_ID 分组的日期之间的平均时间（以月为单位）。换句话说，对于数据中的每个主题，我需要知道与该主题相关的事件之间的平均月数。每个主题都有不同数量的相关事件。有没有相对简单的方法可以做到这一点？我知道如何在 R 中做到这一点，但我对 SAS 还比较陌生，还没有找到解决方案。

提前感谢这个社区提供的任何帮助！

主题ID 活动日期
1 日期_1
1 日期_2
1 日期_3
2 日期_1
2 日期_2
3 日期_1
3 日期_2
3 日期_3
3 日期_4
3 日期_5
3 日期_6
4 日期_1
4 日期_2
5 日期_1
5 日期_2
5 日期_3
5 日期_4
6 日期_1
6 日期_2
date

1 个回答

  1. Best Answer

    在 SAS 中，您可以利用按组处理。我们知道我们需要将每个日期与前一个日期进行比较，但我们不想对组中的第一个日期进行此操作。要完成此任务，我们需要了解两个函数：

    1. lag()：获取前一行的值
    2. intck()：计算两个日期之间的时间间隔（例如天、月、年等）

    对于除第一行之外的每一行，我们想要运行itnck('month', lag(date), date)该函数来计算事件之间的月份数。但是滞后函数有点特殊，在条件语句中的表现并不如预期，所以我们只需在每一行上运行它，并将每组中的第一行设置为缺失值。

    从那里，您可以运行 SQL 或 PROC MEANS 之类的程序来获取每个组日期之间的平均值。

    data have;
    format date date9.;
    input id date:date9.;
    datalines;
1 01JAN2024
1 08FEB2024
1 12APR2024
2 04JAN2024
2 21APR2024
3 06MAY2024
3 09JUL2024
3 12JUL2024
3 18AUG2024
;
run;

data diffs;
    set have;
    by id;

    months_dif = intck('month', lag(date), date);

    if(first.id) then months_dif = .;
run;

/* Get the average per month using SQL */
proc sql;
    create table want as
        select id, mean(months_dif) as avg_months_dif
        from diffs
        group by id
    ;
quit;

/* Alternatively you can use proc means */
proc means data=diffs noprint;
    by id;
    output out=want(drop=_:)
        mean(months_dif) = avg_months_dif
    ;
run;

    id  avg_months_dif
1   1.5
2   3
3   1
    • 1

相关问题