主页 / coding / 问题 / 78943970
Accepted
m4rc
Asked: 2024-09-03 18:53:25 +0800 CST

XSLT 组织列表列表

  • 772

我正在尝试重新制作列表列表，从 XML 转换为专有的基于 XML 的文件格式。

本质上输入是这样的

<ul>
  <li>Item 1</li>
  <li><ul><li>Sub item 1</li><li>Sub item 2</li></ul></li>

  <li>Item 2</li>
  <li><ul><li>Sub item 3</li><li>Sub item 4</li></ul></li>
</ul>

显然看起来像这样：

  • 第 1 项
    • 子项目 1
    • 子项目 2
  • 第 2 项
    • 子项目 3
    • 子项目 4

但我需要子项列表li与其各自的标题位于同一个标签内。因此，如下所示：

  • 第 1 项
    • 子项目 1
    • 子项目 2
  • 第 2 项
    • 子项目 3
    • 子项目 4

当我测试上面的原始输入时，我似乎无法想出一个 XPATH，它会选择我的第一个子项ul而不选择第二个子项ul。

当通过转换运行时，这基本上会创建

<ul>
  <li>Item 1
    <ul><li>Sub item 1</li><li>Sub item 2</li></ul>
    <ul><li>Sub item 3</li><li>Sub item 4</li></ul>
  </li>

  <li>Item 2
    <ul><li>Sub item 3</li><li>Sub item 4</li></ul>
  </li>
</ul>

让我走到这一步的 XPath 是

following-sibling::li[not(normalize-space(text()))]/*[1][self::ul or self::ol]

normalize-space 是隔离li没有文本但里面只有ul或的ol元素。我尝试了上述的多种变体，设置索引 [1] 只会返回所有元素，而 [2] 则不返回任何元素。

我有点困惑，感谢任何意见或建议！

xpath

2 个回答

  1. Best Answer

    这似乎是一个分组问题，您可以在 XSLT 2 或更高版本（XSLT 的当前版本是 3.0）中使用以下方法解决for-each-group group-starting-with：

      <xsl:template match="ul[.//ul]">
    <xsl:copy>
      <xsl:for-each-group select="li" group-starting-with="li[not(ul)]">
        <xsl:copy>
          <xsl:apply-templates select="node(), tail(current-group())/*"/>
        </xsl:copy>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>

    示例小提琴在这里。

    • 1

  2. 在 XSLT 1.0 中，您可以使用key：

    <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output indent="true"/>
  
  <!-- 
    Index child lists by the identifier of their "header" list item
  -->
  <xsl:key 
    name="child-lists-by-header-li" 
    match="li/ul"
    use="generate-id(parent::li/preceding-sibling::li[not(ul)][1])"
  />

  <!-- 
    Render a list by rendering just the "header" list items; those that doesn't 
    have child lists. Those "header" list items will render their own child lists
  -->
  <xsl:template match="ul">
    <xsl:copy>
      <xsl:apply-templates select="li[not(ul)]"/>
    </xsl:copy>
  </xsl:template>
  
  <!-- 
    Render a list by rendering its own content, and then all of its child lists
  -->
  <xsl:template match="li">
    <xsl:copy>
      <xsl:apply-templates/>
      <xsl:apply-templates select="key('child-lists-by-header-li', generate-id(.))"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>
    • 1

相关问题