主页 / coding / 问题 / 78899105
Accepted
Rod
Asked: 2024-08-22 05:48:53 +0800 CST

Excel 中有没有办法从 a 点到达 b 点

  • 772

我想从点 a 到达点 b，如下所示。我以为这是一个转置解决方案，但它似乎没有按照我的想法工作。

基本上，我试图想出一种方法来轻松收集/管理数据（点 A），然后以某种方式显示它（点 B）。

尝试了解如何通过 Excel 方式或编程方式解决这个问题？

点A

在此处输入图片描述

B点

在此处输入图片描述

excel

3 个回答

  1. 使用 MATCH 函数可行：

    假设您在 Sheet1 上有第一个表格。

    工作表1

    在 Sheet2 上，按照您所做的方式命名您的列：

    工作表2

    现在，在单元格 B2 中复制并粘贴以下内容：

    =IF(SUM(ISNUMBER(MATCH(Sheet1!$A$2:$A$5,$A2,0))*ISNUMBER(MATCH(Sheet1!$B$2:$B$5,B$1,0)))>0,"x","")

    然后拖动单元格的角以填充整个表格。

    单元格 B2 的细分

    我们尝试查看 Sheet1 的 A 列中的每个单元格是否与行标题 (server1) 的内容匹配：

    MATCH(Sheet1!$A$2:$A$5,$A2,0)

    其评估结果类似于{1, 1, #N/A, #N/A}。

    然后，我们只保留数字单元格ISNUMBER（请注意 $A2 上的 $ 符号的位置，它锁定了列但不锁定行，以便在拖动单元格的角时保持指向列标题）：

    ISNUMBER(MATCH(Sheet1!$A$2:$A$5,$A2,0))

    其评估结果类似于{TRUE, TRUE, FALSE, FALSE}。

    我们对列标题执行相同的操作（这次我们锁定行 B$1 以保留标题），并将两个数组相乘。我们最终得到{TRUE * TRUE, TRUE * FALSE, FALSE * TRUE, FALSE * FALSE}，其计算结果为{1, 0, 0, 0}。

    我们使用 将所有这些数字相加SUM，并且简单地IF说，如果总和等于或大于 1，那么我想要显示一个x。

    • 2
  2. Best Answer

    如果您有 Excel 365：

    在此处输入图片描述

    =LET(
    serverdata, A2:A5,
    servicesdata, B2:B5,
    servers, UNIQUE(serverdata),
    services, TRANSPOSE(UNIQUE(servicesdata)),
    matchMatrix, IF(COUNTIFS(serverdata, servers, servicesdata, services) > 0, "x", ""),
    VSTACK(HSTACK("", services), HSTACK(servers, matchMatrix))
)

    serverdata：引用服务器输入范围

    servicesdata：参考服务输入范围

    服务器：从服务器数据中提取唯一的服务器名称

    服务：从服务数据中提取唯一的服务名称并将其转置为行格式。

    matchMatrix：检查每个服务器和服务组合。如果找到匹配项（即服务器提供该服务），则放置“x”；否则，将单元格留空。

    VSTACK：将标题行（服务）堆叠在匹配矩阵的顶部，从空白单元格开始

    HSTACK：将服务器名称堆叠在匹配矩阵的左侧。

    匹配时填充 x

    • 0

  3. 它被称为数据透视表： 在此处输入图片描述

    创建表有几个步骤。

    • 0

相关问题