主页 / coding / 问题 / 78323197
Accepted
yelldio
Asked: 2024-04-14 16:35:43 +0800 CST

来自多个数组的 Google Sheets 中带有 Arrayformula 的 SUMIFS

  • 772

https://docs.google.com/spreadsheets/d/1JvZerzOiW0vdewnfZT47WuU3TPlW15UHUSpvII1HE50/edit#gid=0

我想使用 arrayformula 数组函数和单元格 N4 中的一个公式来通过 SUMIFS 获取该表中的 q'ty 值。

我确实喜欢这个 =ArrayFormula(sumifs($E$4:$E$29,$B$4:$B$29,N3:S3,$D$4:$D$29,M4:M20,$C$4:$C$29,L4:L20))

但我想我得到了错误的答案。

google-sheets

2 个回答

  1. 使用query()，像这样：

    =query( 
  A3:E, 
  "select Col3, Col4, sum(Col5) 
   where Col1 is not null 
   group by Col3, Col4 
   pivot Col2", 
  1 
)

    如果没有数据，公式将显示空白。要填充零而不是空格，请使用以下命令：

    =let( 
  table, query( 
    A3:E, 
    "select Col3, Col4, sum(Col5) 
     where Col1 is not null 
     group by Col3, Col4 
     pivot Col2", 
    1 
  ), 
  arrayformula(if(table = "", 0, table)) 
)

    请参阅query()和let()。

    • 1
  2. Best Answer

    我建议QUERY按照@doubleunary的建议使用，但如果你想这样做，SUMIFS你可以使用该MAP函数：

    =MAP(N3:S3,LAMBDA(m,MAP(L4:L20,M4:M20,LAMBDA(s,i,SUMIFS(E4:E,B4:B,m,C4:C,s,D4:D,i)))))

    或者您可以使用SUMIF连接的条件和条件范围：

    =ARRAYFORMULA(SUMIF(B4:B&C4:C&D4:D,N3:S3&L4:L20&M4:M20,E4:E))

    编辑：使用 MAKEARRAY 的解决方案

    =MAKEARRAY(ROWS(L4:M20),COLUMNS(N3:S3),LAMBDA(r,c,SUMIFS(E4:E,B4:B,INDEX(N3:S3,,c),C4:C,INDEX(L4:L20,r),D4:D,INDEX(M4:M20,r))))
    • 0

相关问题