主页 / coding / 问题 / 78300861
Accepted
Enlico
Asked: 2024-04-10 04:03:23 +0800 CST

我可以使用 StateT/MaybeT/forever 来消除此 IO 操作中的显式递归吗？

  • 772

我有一个这样的程序

start :: [Q] -> R -> IO R
start qs = fix $ \recurse r -> do
  q <- select qs
  (r', exit) <- askQ q r
  (if exit
    then return
    else recurse) r'

它需要一个问题列表Q、一个Report，并在 monad 中返回一个新的Report，IO因为select需要它随机选择一个问题（也因为askQ将等待用户键盘输入）；但是，用户没有选择exit执行时askQ，start会递归调用自身。（fix $ \recurse这是编写递归 lambda 的技巧。）

上面的代码听起来很像以下几件事：

但无法真正判断是否可以使用这些抽象中的任何一个或多个以更惯用的方式编写上述代码，最重要的是避免显式递归。

haskell

2 个回答

  1. Best Answer

    嗯，结果会是这样的：

    type M = MaybeT (StateT R IO)

start :: [Q] -> M ()
start qs = forever (select qs >>= askQ)

    这假设select和askQ将被重写以在Mmonad 中运行，而不是IO：

    select :: [Q] -> M Q
askQ :: Q -> M ()

    结果非常……简洁。

    对于后代来说，这是一个独立的例子......

    import Data.Coerce
import Control.Applicative
import Control.Monad
import Control.Monad.State
import Control.Monad.Trans.Maybe
import System.Random

newtype Q = Q String deriving (Show)
newtype R = R [String] deriving (Show)

type M = MaybeT (StateT R IO)

runM :: M a -> IO (Maybe a, R)
runM = flip runStateT (R []) . runMaybeT

select :: [Q] -> M Q
select qs = (qs !!) <$> randomRIO (0, length qs - 1)

askQ :: Q -> M ()
askQ (Q q) = do
  liftIO $ putStrLn q
  r <- liftIO getLine
  if r == "exit" then mzero
    else modify (coerce (r:))

start :: [Q] -> M ()
start qs = forever (select qs >>= askQ)

main :: IO ()
main = do
  result <- runM $ start [ Q "Is this idiomatic?"
                         , Q "Seriously, what's wrong with recursion?"
                         ]
  print result

    这似乎有效：

    λ> main
Seriously, what's wrong with recursion?
nothing
Is this idiomatic?
yes
Is this idiomatic?
exit
(Nothing,R ["yes","nothing"])
    • 5

  2. 因为我最近一直在研究递归方案，所以我想我应该尝试一下单子同态

    import Data.Functor.Foldable.Exotic
import Data.Functor.Base (NonEmptyF(..))

start qs = hyloM alg coalg where
  -- Build up a non-empty list ending with the final report.
  coalg r = do q <- select qs
               (r', exit) <- askQ q r
               return $ NonEmptyF r' (if exit then Nothing else Just r')

  -- Wade through the "other" reports to get to the last one.
  alg (NonEmptyF _ (Just x)) = return x
  alg (NonEmptyF r Nothing) = return r

    几乎可以肯定这里还有改进的空间。（在我的脑海中，我相当确定不良报告列表没有被“融合”掉。）

    • 0

相关问题