主页 / coding / 问题 / 78275659
Accepted
horanimal
Asked: 2024-04-05 01:37:55 +0800 CST

输出项目列表的所有唯一组合

  • 772

例如，给定输入数组 [A,B,C,D]，输出应为： [A,B,C,D,AB,AC,AD,BC,BD,CD,ABC,ABD,ACD,BCD ，A B C D]

我发现的大多数答案都涉及将多个列表组合在一起或包含“AA”或“AB”和“BA”等输出 - 这是我不想要的。

我还希望公式根据输入数组的大小动态放大或缩小并过滤掉空白，这样我就可以简单地指向它，说“A1：A”，然后当我向 A 列添加或删除值时我的独特组合列表已更新。

例如，如果输入数组为 [A,B,C]，则输出将为 [A,B,C,AB,AC,BC,ABC]。

google-sheets-formula

2 个回答

  1. Best Answer

    这是一种方法，但它可以容纳输入数组的最大18计数并发布其达到 lambda 计算限制：

    =let(Σ,unique(tocol(A:A,1)), Δ,tocol(byrow(index(int(mod(sequence(2^rows(Σ))/2^sequence(1,rows(Σ),0),2))),lambda(Λ,join(,filter(torow(Σ),Λ)))),3),
 sort(Δ,len(Δ),1,1,1))

    在此输入图像描述

    后端矩阵逻辑：

    在此输入图像描述

    • 1

  2. 另一个解决方案：

    =ARRAYFORMULA(LET(
    list,TOCOL(UNIQUE(A:A),1),size,ROWS(list),idx,SEQUENCE(size),
    binary_array,SEQUENCE(1,size)*REGEXEXTRACT(BASE(SEQUENCE(2^size-1),2,size),REPT("(.)",size)),
    result,BYROW(VLOOKUP(binary_array,{idx,list},2,0),LAMBDA(row,JOIN(,IFNA(row)))),
    SORT(result,LEN(result),1,result,1)))

    在此输入图像描述

    让n为列表中值的数量。该公式创建一个大小为二进制的数组2^n-1 x n，并将其每一行乘以1 x n从 到1的值数组n

    SEQUENCE(1,size) * REGEXEXTRACT(BASE(SEQUENCE(2^size-1),2,size),REPT("(.)",size))

    在此输入图像描述

    然后它VLOOKUP对此数组执行 a ，其中查找列是n x 1从 到1的值数组n，结果列是输入数组 (A1:A3)。

    VLOOKUP(binary_array,{idx,list},2,0)

    在此输入图像描述

    之后，我们删除错误并执行逐行连接BYROW

    在此输入图像描述

    最后我们得到SORT结果，首先按长度，然后按字典顺序：

    SORT(result,LEN(result),1,result,1)

    在此输入图像描述

    • 1

相关问题