主页 / coding / 问题 / 77888362
Accepted
con
Asked: 2024-01-27 02:34:26 +0800 CST

Perl 的日期时间未返回正确的时间差异

  • 772

受https://perlmaven.com/datetime的启发，我试图找到 2024-01-03T19:00:00 和 2024-01-07T16:00:00 （93 小时）之间的差异小时数。

#!/usr/bin/env perl

use 5.038;
use warnings FATAL => 'all';
use autodie ':default';
use DDP;
use Devel::Confess 'color';
use DateTime;

sub str_to_date ($date) {
    if ($date =~ m/^(\d+) # year
    \-(\d{1,2})           # month
    \-(\d{1,2})           # day
    T
    (\d+)                        # hour
    :
    (\d+)                        # minutes
    :
    (\d+)                        # seconds                  
    /x) {
        return DateTime -> new(
        year  => $1,
        month => $2,
        day   => $3,
        hour    => $4,
        minute=> $5,
        second=> $6,
    );
    } else {
        die "$date failed regex.";
    }
} # later dates are "greater"
my $wed_date = str_to_date('2024-01-03T19:00:00');
say $wed_date->day;
my $sun_date = str_to_date('2024-01-07T16:00:00');
my $diff = $sun_date - $wed_date; # returns a duration object

p $diff;
say $diff->clock_duration->in_units('hours'); # 21, but should be 93
say $diff->in_units('hours'); # 21 again
say $diff->hours; # 21 again
say $sun_date->delta_days($wed_date)->in_units('hours'); # 0
p $diff->deltas;

我从https://metacpan.org/pod/DateTime::Format::Duration找到的所有方法都给出了错误的答案。

或者，如果我删除解析，

#!/usr/bin/env perl
use 5.038;
use warnings FATAL => 'all';
use autodie ':default';
use DDP;
use Devel::Confess 'color';
use DateTime;

my $wed_date = DateTime->new(
    year => 2024,
    month=>1,
    day=>3,
    hour=>19
);#str_to_date('2024-01-03T19:00:00');
my $sun_date = DateTime->new(
    year=>2024,
    month=>1,
    day=>7,
    hour=>16#my $sun_date = str_to_date('2024-01-07T16:00:00');
);#
say $wed_date->day;

my $diff = $sun_date - $wed_date;

p $diff;
say $diff->clock_duration->in_units('hours'); # 21, but should be 93
say $diff->in_units('hours'); # 21 again
say $diff->hours; # 21 again
say $sun_date->delta_days($wed_date)->in_units('hours'); # 0
p $diff->deltas; # 10

答案是相同的。

DateTime::Duration 对象似乎忽略了中间的天数，而只关注小时之间的差异。

如何获得两个日期之间正确的小时数？

datetime

2 个回答

  1. 答案，根据https://metacpan.org/pod/DateTime#How-DateTime-Math-Works

    $sun_date->subtract_datetime_absolute($wed_date)->seconds;

    这是一个 DateTime::Duration 对象：

    DateTime::Duration  {
    public methods (34): add, add_duration, calendar_duration, clock_duration, clone, compare, days, delta_days, delta_minutes, delta_months, delta_nanoseconds, delta_seconds, deltas, end_of_month_mode, hours, in_units, inverse, is_limit_mode, is_negative, is_positive, is_preserve_mode, is_wrap_mode, is_zero, MAX_NANOSECONDS, minutes, months, multiply, nanoseconds, new, seconds, subtract, subtract_duration, weeks, years
    private methods (8): _add_overload, _compare_overload, _duration_object_from_args, _has_negative, _has_positive, _multiply_overload, _normalize_nanoseconds, _subtract_overload
    overloads: *, +, -, <=>, cmp
    internals: {
        days           0,
        end_of_month   "wrap",
        minutes        0,
        months         0,
        nanoseconds    0,
        seconds        334800
    }
}

    秒数 334800 等于 93 小时，这是正确答案。

    感谢评论者。

    • 1
  2. Best Answer

    使用->delta_ms而不是->subtract_datetime（通过减法调用的方法）。

    以天为单位的持续时间无法转换为小时，因为并非所有天都有相同的小时数。事实上，只有这些转换是安全的：

    • 周 ⇔ 天
    • 小时 ⇔ 分钟
    • 秒 ⇔ 纳秒

    因此，->in_units( 'hours' )仅将持续时间的小时和分钟部分转换为小时。

    $sun_date - $wed_date返回 3 天 1260 分钟的持续时间。
    ->in_units( 'hours' )返回 int( 0 + 1260/60 ) = 21 小时。

    解决方案是创建由小时和/或分钟而不是天组成的持续时间。

    $sun_date->delta_ms( $wed_date )返回 5580 分钟的持续时间。
    ->in_units( 'hours' )返回 int( 0 + 5580/60 ) = 93 小时。

    • 1

相关问题