如何选择由两个不同的字符串模式分隔的字符串

我可能会像往常一样逐行处理这些行，并查看第一个空格分隔的字段以识别主题和 alt-name 行。然后，您可以使用标点符号将该行拆分到另一个数组，并从那里选择正确的部分。（这是假设该CN部分之前没有任何内容——我不记得是否允许这样做。）如果您真的想检查周围的文本（CN=和DNS:部分），那么我会改用 Perl，然后去查看meuh 的答案。

awk '$1 == "subject" { subject=$2; split($2, a, "[=,]"); cn=a[2]; } 
     $1 == "subject-alternative-name" { split($2, a, "[\":]"); altname=a[3]; }
     END { out = "openssl ... -keyout " cn "_2025.key -subj "  subject; 
           if (altname) out = out " -altname \"subjectAltName = DNS:" altname "\"";
           print out 
     } '  < whatever.txt
openssl ... -keyout foo.whatever.com_2025.key -subj "CN=foo.whatever.com,O=XYZ,L=Toronto,ST=Ontario,C=CA" -altname "subjectAltName = DNS:bar.whatever.com"

使用 GNU awk 中的正match(string, regexp, arrayresult)则()表达式来捕获所需部分。例如

awk '
BEGIN  {F=" "; FS = "\n"; RS = ""; OFS = "\n"}
{ match($17, "CN=([^,]*)", x);
  cn = x[1]
  match($17, "\"(.*)\"", x)
  subject = x[1]
  if(match($18, "(DNS:.*)\"", x)>0){
   dns = x[1]
   toadd = " -addext \"subjectAltName = " dns "\""
  }
  print "openssl req -new -nodes -sha256 -newkey rsa:2048 -out " \
   cn "_2025.csr -keyout " \
   cn "_2025.key -subj \"/" \
   subject "\"" toadd
}'

为了回答OP关于为什么他们的代码使用来自line 1...的数据的问题，请检查的内容RSTART。您应该会发现，因为没有运行RSTART=0任何函数（例如）来实际填充。match()RSTART

我建议不要将整个输出处理为单独的行，而是将其处理为一个段落。

一种不同的awk方法：

$ cat whatever.com | awk -F'"' '            # set double quotes as field delimiter
{ gsub(/[[:space:]]/,"",$1)                 # trim white space from 1st field
  if ($1=="subject")
     subject=$2                             # save for later use
  else
  if ($1=="subject-alternative-name")
     print "openssl req -new -nodes -sha256 -newkey rsa:2048 -out whatever.com_2025.csr -keyout whatever.com_2025.key -subj \"/" subject "\" -addext \"subjectAltName = " $2 "\""
}'

这将生成：

openssl req -new -nodes -sha256 -newkey rsa:2048 -out whatever.com_2025.csr -keyout whatever.com_2025.key -subj "/CN=whatever.com,O=XYZ,L=Toronto,ST=Ontario,C=CA" -addext "subjectAltName = DNS:whatever.com"

这假设您可以逐行处理，而不必进行所有现场和记录扭曲。它还假设subject-alternative-name始终存在：

# Capture domain name in "subject" field, which starts with "CN=" and ends with a comma, and whole field too
/ +subject .*CN=[^,]+,O=/ {
  match($2, /"(CN=([^,]+),O=[^"]+")/, arr);
  domain=arr[2];
}

# Only print once we ascertain whether "DNS" is present in "subject-alternative-name" field
/ +subject-alternative-name / {
  # If we have "DNS" keyword, print with "-addext", otherwise print without
  if (match($2, /"(DNS:[^"]+)/, altarr))
    printf "openssl req -new -nodes -sha256 -newkey rsa:2048 -out %s_2025.csr -keyout %s_2025.key -subj \"/%s -addext \"subjectAltName = %s\"\n", domain, domain, arr[1], altarr[1];
  else
    printf "openssl req -new -nodes -sha256 -newkey rsa:2048 -out %s_2025.csr -keyout %s_2025.key -subj \"/%s\n", domain, domain, arr[1];
}

使用DNS关键字：

$ awk -f /tmp/UL_789631.awk < /tmp/UL_789631.txt 
openssl req -new -nodes -sha256 -newkey rsa:2048 -out whatever.com_2025.csr -keyout whatever.com_2025.key -subj "/CN=whatever.com,O=XYZ,L=Toronto,ST=Ontario,C=CA" -addext "subjectAltName = DNS:whatever.com"

不带DNS关键字：

$ awk -f /tmp/UL_789631.awk < /tmp/UL_789631.txt 
openssl req -new -nodes -sha256 -newkey rsa:2048 -out whatever.com_2025.csr -keyout whatever.com_2025.key -subj "/CN=whatever.com,O=XYZ,L=Toronto,ST=Ontario,C=CA"

这使用正则表达式子表达式来捕获相关部分。该match函数执行正则表达式匹配并将子表达式（括号中的子表达式）分配给数组（此处arr为subject字段和altarr字段subject-alternative-name）。我们使用两个（重叠）子表达式subject：一个用于字段值，一个用于字段值内的域名。

第一/.../ {行匹配主题字段（请注意空格，这样它就不会匹配以“subject”开头的其他字段）。第一个括号提取match字段内容，第二个括号提取域名。

的目的[^,]+是以非贪婪的方式匹配直到（下一个）逗号分隔符的所有内容并排除它。如果您使用.+,，它将捕获直到 的所有内容C=CA。

在此匹配结束时，arr包含整个正则表达式、字段字符串和域字符串。

我们暂时不打印，因为我们还不知道要包含什么。（如果您愿意，也可以打印部分行，然后添加END { printf "\n"}.）

匹配/ +subject-alternative-name 查看关键字的第二个字段DNS，捕获整个字段值，如果匹配，则打印适当的扩展命令，否则打印常规命令。

祝你开心快乐！