可能存在更多我不知道的在 fish 中重命名的惯用方法，但是如果您将其放在命令替换string replace中，您的循环方法就会起作用：

# fish 3.1.0 or newer
for file in *\ *
  mv -n -- $file (
    string replace -a -- ' ' _ $file |
      string collect
  )
end

注意管道string collect(需要 fish 3.1.0 或更新版本) 可以防止对换行符进行拆分，因此可以对任意文件名进行拆分。string replace但尾随换行符 (由 添加的换行符以及文件名末尾的换行符（如果有）) 会丢失。

最新版本fish（3.4.0 或更新版本）现已添加对$(...)Korn 风格命令替换的支持，该命令替换可以在双引号内使用，从而避免拆分，并且无需string collect：

# fish 3.4.0 or newer
for file in *\ *
  mv -n -- $file "$(string replace -a -- ' ' _ $file)"
end

通过使用 NUL 分隔的字符串，可以保留文件名中的尾随换行符（如果有）：

# fish 3.5.0 or newer
for file in *\ *
  mv -n -- $file (
    string join0 -- $file |
      string replace -a ' ' _ |
      string split0
  )
end

但是，如果您用下划线替换空格，那么您可能还想用\n下划线替换其他空格字符（包括换行符，又名），这可能只是：

for file in *
  set new (string replace -ra -- '\s' _ $file) &&
    mv -n -- $file $new 
end

（仅替换 ASCII空格\r，，，，，，）或：\n\t\v\f

for file in *
  set new (string replace -ra -- '(*UCP)\s' _ $file) &&
    mv -n -- $file $new 
end

根据nicode字符特性来匹配 Unicode 中归类为空白的其他字符（包括不间断空格、表意空格和其他几十种字符）。UCP

替换*\ *为{.,}*\ *（*用{,.}*）也处理隐藏文件。

rename

这种方法并不只适用于 fish。重命名多个文件最简单的方法可能是使用 Perl 的rename。要将空格转换为下划线，您需要：

rename 'y/ /_/' *

如果文件也在子目录中，您可以使用 globstar或者find：

find . -maxdepth 1 -type f -iname "*.jpg" -execdir rename "y/ /_/" {} +

参考

• 根据这个答案
• 如何：Linux 在 Shell 提示符下重命名多个文件 – nixCraft
• 有关 的更多信息y/，请翻译而不是替代。
• DistroTube - Linux 中重命名文件的工具