Início / unix / Perguntas / 793509
Accepted
Ahmad Ismail
Asked: 2025-04-09 18:25:23 +0800 CST

Pare o cursor em aspas simples e duplas

  • 772

Eu tenho um zle como:

function _ctrl-shift-left() {
    ((REGION_ACTIVE)) || zle set-mark-command # Selection
    zle backward-word
}

zle -N _ctrl-shift-left
bindkey '^[[1;6D' _ctrl-shift-left # Ctrl+Shift+Left to select till the beginning of the previous word.

Por exemplo, para o comando abaixo

$ curl -s "https://samplesite.com/101146/07/data-processing/13/?#/101146-132519042909.html" | grep -oP 'https://dl\d*\.samplesite\.com/Files/[^"]+\.rar' | sed 's/\?nocache=[^&]*//g'

quando pressiono ctrl-shift-left, quero parar o cursor em 'e ".

Como posso fazer isso?

zsh

2 respostas

  1. Best Answer

    Por padrão, para backward-wordtodos os widgets de movimento/ação de palavras, as palavras são caracteres alfanuméricos mais os caracteres em $WORDCHARS(semelhante ao $wordcharsdo tcsh), mas você também pode usar a select-word-stylefunção autocarregável para alterar essa definição de palavra.

    autoload -Uz select-word-style
select-word-style shell

    Mudará a definição da palavra :

    shell
    Palavras são argumentos completos de comando do shell, possivelmente incluindo strings completas entre aspas ou quaisquer tokens especiais do shell.

    Então em seu

    $ curl -s "https://samplesite.com/101146/07/data-processing/13/?#/101146-132519042909.html" | grep -oP 'https://dl\d*\.samplesite\.com/Files/[^"]+\.rar' | sed 's/\?nocache=[^&]*//g'
  ⇑    ⇑  ⇑                                                                                 ⇑ ⇑    ⇑   ⇑                                                 ⇑ ⇑   ⇑

    backward-wordlevará você aos lugares marcados ⇑acima.

    Não é exatamente isso que você está pedindo, pois não vai parar na "entrada [^"], mas suspeito que seja isso que você realmente quer.

    Também é possível criar um widget a partir dessa select-word-stylefunção e vinculá-lo a alguma combinação de teclas para selecionar o estilo da palavra interativamente:

    autoload -Uz select-word-style
zle -N select-word-style
bindkey '\ez' select-word-style

    Então, pressionar Alt+ zmostrará este prompt:

    $
Word styles (hit return for more detail):
(b)ash (n)ormal (s)hell (w)hitespace (d)efault (q)uit
(B), (N), (S), (W) as above with subword matching
?

    Com mais detalhes:

    $
Word styles (hit return for more detail):
(b)ash (n)ormal (s)hell (w)hitespace (d)efault (q)uit
(B), (N), (S), (W) as above with subword matching
(b)ash:       Word characters are alphanumerics only
(n)ormal:     Word characters are alphanumerics plus $WORDCHARS
(s)hell:      Words are command arguments using shell syntax
(w)hitespace: Words are whitespace-delimited
(d)efault:    Use default, no special handling (usually same as `n')
(q)uit:       Quit without setting a new style

    Alternativamente, você pode especificar que o shellestilo de palavra deve ser usado no contexto do seu _ctrl-shift-leftwidget zle com:

    zstyle :zle:_ctrl-shift-left word-style shell

    Ou talvez mais próximo do que você está perguntando:

    zstyle :zle:_ctrl-shift-left word-style unspecified
zstyle :zle:_ctrl-shift-left word-chars \'\"

    Que salta para 'e "somente caracteres.

    • 1

  2. OP aqui. Enquanto isso, criei uma solução usando Como fazer com que os comandos do zsh no estilo vi respeitem WORDCHARS?

    O código é fornecido abaixo:

    SEPCHARS="[ '\"]"

my-forward-word() {
    if [[ "${BUFFER[CURSOR + 1]}" =~ "${SEPCHARS}" ]]; then
        (( CURSOR += 1 ))
        return
    fi
    while [[ CURSOR -lt "${#BUFFER}" && ! "${BUFFER[CURSOR + 1]}" =~ "${SEPCHARS}" ]]; do
        (( CURSOR += 1 ))
    done
}

zle -N my-forward-word

my-backward-word() {
    if [[ "${BUFFER[CURSOR]}" =~ "${SEPCHARS}" ]]; then
        (( CURSOR -= 1 ))
        return
    fi
    while [[ CURSOR -gt 0 && ! "${BUFFER[CURSOR]}" =~ "${SEPCHARS}" ]]; do
        (( CURSOR -= 1 ))
    done
}

zle -N my-backward-word
    • 0

relate perguntas