Início / unix / Perguntas / 791417
Accepted
Ismael Sanchez
Asked: 2025-02-22 00:26:19 +0800 CST

Como gerar dois arquivos de saída a partir da instrução if/else usando o awk?

  • 772

Das informações abaixo:

$ cat access.dat
2025/01/01T10:00:01 "GET" /path/resource/api1 User1 500
2025/01/01T10:00:01 "DELETE" /path/resource/api1 User1 503
2025/01/01T04:00:01 "GET" /path/resource/api1 User1 500
2025/01/01T03:00:01 "GET" /path/resource/api1 User1 503
2025/01/01T05:00:01 "PUT" /path/resource/api1 User2 500
2025/01/01T06:00:01 "GET" /path/resource/api1 User1 200
2025/01/01T07:00:01 "GET" /path/resource/api1 User1 201
2025/01/01T08:00:01 "GET" /path/resource/api2 User1 500
2025/01/01T09:00:01 "POST" /path/resource/api2 User2 500
2025/01/01T10:00:01 "POST" /path/resource/api2 User1 400
2025/01/01T11:00:01 "GET" /path/resource/api2 User2 404

Estou tentando gerar um script awk com a instrução if else. Ao fazer isso

cat access.dat | awk '{if ($NF>=400) {print $0}} > failure.dat

o arquivo de saída é gerado com sucesso. Mas ao adicionar

cat access.dat | awk '{if ($NF>=400) {print $0} > failure.dat else {print$0} > success.dat}

está marcando erro. O que está errado no meu script awk? Como eu poderia gerar tanto failure.dat quanto success.dat dentro da instrução if/else?

Obrigado pela ajuda.

awk

3 respostas

  1. Best Answer

    Você precisa colocar os nomes dos arquivos entre aspas para evitar awktratá-los como variáveis:

    awk '{
    if ($NF>=400) {print > "failure.dat"}
    else {print > "success.dat"}
}' file

    e você precisa fazer o redirecionamento dentro das chaves.

    Você também pode encurtá-lo usando o operador ternário:

    awk '{print > (($NF < 400 ? "success" : "failure")".dat")}'

    (O parêntesis externo é necessário em algumas awkimplementações).

    • 8

  2. Ainda mais claro:

    awk -v Ok=success.dat -v No=failure.dat '{ print > ($NF>=400 ? No : Ok) }' access.dat
    • 5

  3. Sua sintaxe é estranha. Não entendo por que você tem o >outside the { }block. Esta é uma maneira mais natural (na minha opinião, pelo menos) de escrever:

    awk '{if ($NF>=400) print > "failure.dat"; else print > "success.dat"}' access.dat

    Ou, um pouco mais claramente:

    awk '
{ 
  if ($NF>=400)
    print > "failure.dat"
   
  else
    print > "success.dat"
}' access.dat

    E, só por diversão, de forma menos clara, mas mais concisa:

    awk '{k = $NF>=400 ? "failure.dat" : "success.dat"; print > k}' access.dat
    • 4

relate perguntas