Início / unix / Perguntas / 788444
Accepted
jsx97
Asked: 2024-12-20 19:34:19 +0800 CST

Exclua recursivamente arquivos vazios e, em seguida, diretórios vazios

  • 772

O script a seguir exclui de forma não recursiva arquivos vazios comuns, sem incluir os com ponto, e então exclui de forma não recursiva diretórios vazios, sem incluir os com ponto, e ignorando a presença de .DS_Storearquivos (ou seja, se o diretório contiver apenas um .DS_Storearquivo, esse diretório será excluído mesmo assim).

rm -f -- *(.L0)

setopt extended_glob
has_files_other_than_DS_Store() [[ -n $REPLY/^(#i).ds_store(#qNDY1) ]]
remove_empty_macos_dirs() {
  local dir ret=0
  for dir do
    rm -f -- $dir/.(#i)ds_store(N.) && rmdir -- $dir || ret=$?
  done
  return $ret
}
remove_empty_macos_dirs *(/^+has_files_other_than_DS_Store)

Alguém poderia mostrar como fazer isso funcionar recursivamente? Ou seja, o primeiro passo é deletar recursivamente todos os arquivos regulares vazios. E então deletar recursivamente os diretórios vazios.

Eu tentaria fazer isso sozinho, mas, para ser honesto, estou com medo de experimentar o rmcomando.

zsh

1 respostas

  1. Best Answer

    Para fazer isso recursivamente, você precisa fazer isso em profundidade primeiro, de modo que se, por exemplo, dirAcontiver apenas dirB, ele próprio vazio, você exclua dirBprimeiro para que dirAentão fique vazio e possa ser excluído por sua vez.

    zshglobs têm o odqualificador para ordenação depth-first :o

    set -o extendedglob
zmodload zsh/files # get builtin rm/rmdir for improved performance
                   # and also avoid E2BIG limits of their standalone
                   # equivalents
rmall() {
  # annoyingly zsh's rm builtin complains if not given any argument
  # even with -f
  (( $# == 0 )) || rm -f -- "$@"
}
ret=0
rmall **/*(ND.L0) # remove empty regular files first
for dir (**/*(ND/od)) ()(($#)) $dir/^(#i).ds_store(NDY1) || {
  rmall $dir/.(#i)ds_store(N.) && rmdir -- $dir || ret=$?
}

    Você pode substituir rm/ rmdirpor print -r Would rm/ print -r Would rmdirpara testar primeiro, mas isso não terá necessariamente o mesmo efeito, pois printnão excluirá nenhum arquivo e, portanto, não poderá renderizar diretórios vazios.

    • 2

relate perguntas