Início / unix / Perguntas / 784445
Accepted
dajoto
Asked: 2024-10-03 18:20:07 +0800 CST

A saída da função ZSH para a entrada do prompt atual é ignorada

  • 772

Tenho uma função registrada no ZSH que pesquisa o conteúdo do arquivo sob o caminho atual para uma correspondência e então captura o nome do arquivo resultante. Isso é então vinculado a uma combinação de teclas. A vinculação de teclas, a pesquisa e o resultado funcionam bem (como se retornassem o valor desejado).

Quando estou usando a combinação de teclas, o valor é impresso na linha de shell atual, mas não é reconhecido como entrada real (ou seja, se eu pressionar enter, o valor é considerado vazio e nada é adicionado ao histórico do prompt). Como faço para exibir o resultado como se ele fosse digitado e um valor válido. Eu tentei echo/ print/ printf(assumindo que o resultado seria o mesmo para cada um), mas também anexando BUFFERe definindo CURSOR.

Tenho certeza de que isso está bem documentado e não estou conseguindo encontrar exemplos por causa da falta de terminologia correta. Alguém pode me apontar a direção certa?

zsh

2 respostas

  1. Best Answer

    Imprimir no terminal não pode ajudar você. Isso exibe uma mensagem para o usuário (não estará no lugar certo na tela e confundirá o editor de linha porque altera a posição do cursor do terminal — use zle -Mou zle -Rem vez disso). Isso não é entrada para o shell.

    A variável mágica BUFFERcontém a(s) linha(s) que o usuário está editando e CURSORcontém a posição do cursor de entrada. Você pode alterar o buffer de entrada do usuário e a posição do cursor modificando BUFFERe CURSOR. Então você estava no caminho certo. Para inserir algo no cursor, no entanto, há uma maneira mais fácil: basta anexar à variável mágica LBUFFERe o zsh fará o resto. LBUFFERcontém a entrada do usuário até o cursor, e modificá-la funciona intuitivamente.

    Aqui está um exemplo funcional do meu .zshrcde inserir a saída de um comando no buffer de entrada. Ele insere o nome do branch Git atual quando eu pressiono Alt+ v b.

    vc_insert_branch () {
  LBUFFER+=$(git symbolic-ref --short HEAD 2>/dev/null)
}
zle -N vc_insert_branch
bindkey '^[vb' vc_insert_branch

    Note que este exemplo simples insere a saída do comando como está. Para um nome de arquivo, você provavelmente deve citá-lo caso ele tenha caracteres especiais. Por exemplo, se a saída do comando for A Song.mp3então o código simples acima apenas insere A Song.mp3na linha de comando. Mas para torná-lo útil, ele deve inserir algo que seja um argumento válido para um comando. Use o sinalizador de expansão de parâmetroq- ou para citar a saída do comando, se necessário.q+ 

    insert_file_search_result () {
  LBUFFER+=${(q-)$(search command goes here 2>/dev/null)}
}

    Note que se você quiser fazer uma busca com base na palavra ao redor do cursor, o zsh tem funções auxiliares que poupam você de fazer sua própria análise de linha de comando, e elas também podem cuidar da injeção de novo texto. Em particular, modify-current-argumentsubstitui a palavra shell ao redor do cursor por uma nova palavra shell de sua escolha, que ele cita se necessário. Aqui está uma prova de conceito que mostra como substituir a palavra em que o cursor está pelo arquivo mais recente que contém essa palavra.

    function grep_word_and_reply_with_file_name {
  if [[ -z $ARG ]]; then
    zle -M 'Cursor not in a word'
    return 1
  fi
  local -a files
  files=(${(@0)${$(grep -l -Z -F -e $ARG -- /dev/null *(-.DNom))%$'\000'}})
  if (($#files == 0)); then
    zle -M "No match for $ARG"
    return 1
  fi
  REPLY=$files[1]
}

function grep_word_and_replace_with_file_name {
  autoload -Uz modify-current-argument
  modify-current-argument grep_word_and_reply_with_file_name
}
zle -N grep_word_and_replace_with_file_name
bindkey '\eG' grep_word_and_replace_with_file_name
    • 2

  2. Normalmente eu encontrava minha resposta na próxima coisa que olhava.

    Encontrei alguma inspiração em https://github.com/junegunn/fzf/blob/master/shell/key-bindings.zsh - em particular a fzf-history-widgetfunção. Lá, ele define a LBUFFERvariável com a entrada do usuário (se não for um comando de histórico de revisão) e então chama zle reset-prompt. Testei isso com minha abordagem BUFFER+ CURSORe isso também funciona, mas a LBUFFERabordagem é mais concisa.

    • 0

relate perguntas