Início / unix / Perguntas / 783475
Accepted
Lucas Rey
Asked: 2024-09-14 14:37:32 +0800 CST

AWK busca por vários padrões em um arquivo

  • 772

Estou tentando descobrir como implementar uma pesquisa "AND" de padrões múltiplos em um arquivo. Basicamente, o aplicativo deve fazer algo somente quando TODOS os 3 padrões estiverem presentes em /var/log/messages

Isso funcionará, mas use " OR ":

awk '/writeback error on sector/ || /blk_update_request: I\/O error/ || /xfs_do_force_shutdown/' /var/log/messages

Aparentemente isso não funciona:

awk '/writeback error on sector/ && /blk_update_request: I\/O error/ && /xfs_do_force_shutdown/' /var/log/messages

O que eu preciso é algo como:

  • Verifique /var/log/messages
  • Se TODOS os 3 padrões estiverem presentes nas mensagens, faça algo

Se possível, usando grep, onde posso usar "-f patterns" para usar um arquivo externo onde o usuário pode adicionar outros padrões

Alguém poderia me dar um conselho? Obrigado Lucas

awk

1 respostas

  1. Best Answer
    if 
  awk '
    !a && /writeback error on sector/      {a=1}
    !b && /blk_update_request: I\/O error/ {b=1}
    !c && /xfs_do_force_shutdown/          {c=1}
    a + b + c == 3 {exit} # we have seen enough
    END {exit a+b+c != 3}' /var/log/messages
then
  echo 'All 3 found, not necessarily on the same lines.'
fi

    Ou para a lista de expressões regulares a serem lidas de um arquivo:

    if
  awk '
    !patterns_read {patterns[$0]; next}
    {
      for (pattern in patterns)
        if ($0 ~ pattern) delete patterns[pattern]
    }
    length(patterns) == 0 {exit}
    END {exit length(patterns) != 0}
  ' /path/to/list-of-patterns patterns_read=1 /var/log/messages
then
  echo 'All patterns found.'
fi

    (não testado).

    • 2

relate perguntas