Início / unix / Perguntas / 769815
Accepted
mrjpaxton
Asked: 2024-02-21 23:22:51 +0800 CST

Extrair uma string de um índice de coluna pesquisada na linha abaixo?

  • 772

Estou tentando fazer um script de shell de uso de disco simples (em traço), mas não tenho certeza de como analisar essa string porque não estou familiarizado com a sintaxe do AWK.

Eu uso este comando: df -P -BG /e, por exemplo, ele me dá uma saída como esta:

Filesystem                  xxxxxxxxxx-blocks  Used Available Capacity Mounted on
/dev/mapper/xxx_crypt                    500G  200G      100G      xx% /

Quero extrair a coluna abaixo em "Usado" (e eventualmente "Disponível"), mas não tenho certeza de como devo fazer isso. Eu sei que o AWK tem um comando de pesquisa como este:awk '/Used/ {print}'

Mas não tenho certeza de como colocar a linha abaixo dela. Alguma dica? É muito importante para mim que ele funcione como um canal em uma linha, já que df -P -BG / | awk '...'estou armazenando-o em uma variável shell, mas não é estritamente necessário, suponho, já que o AWK multilinha pode ser usado.

shell

3 respostas

  1. Se sua dfimplementação suportar, você poderá usar --outputem vez de analisar. No man dfmeu Arch Linux:

    --output[=FIELD_LIST]
  use the output format defined by FIELD_LIST, or print all fields if
  FIELD_LIST is omitted.

[...]

FIELD_LIST is a comma-separated list of columns to be included.  
Valid field names  are:  'source',  'fstype',  'itotal',  'iused',
'iavail',  'ipcent', 'size', 'used', 'avail', 'pcent', 
'file' and 'target' (see info page).

    Então, no seu caso, você simplesmente faria:

    $ df  -BG --output="used" /
 Used
  200G

    Se você realmente precisa analisá-lo, eu não me preocuparia com a correspondência de padrões. Você controla a entrada, ela não muda, então basta imprimir o terceiro campo (saída do meu sistema):

    $ df -P -BG / | awk '{print $3}'
Used
44G

    Se você realmente precisa que funcione mesmo que a ordem dos campos mude, então você precisa descobrir qual campo contém a string Used, você pode fazer algo complicado como isto:

    $ df -P -BG / | 
   awk '{ if(NR==1){for(i=1; i<=NF; i++){ if($i ~ /Used/){want=i}}} print $want}'
Used
44G
    • 2
  2. Best Answer

    Usando GNU awk para FPAT, FIELDWIDTHS, \s, \S e gensub():

    $ cat tst.awk
BEGIN { FPAT="\\S+|\\s+"; OFS="\t" }
NR == 1 {
    sub(/Mounted on/,"Mounted_on")
    for ( i=1; i<=NF; i+=2 ) {
        tags[++numTags] = $i
        wids = wids " " length($i $(i+1))
    }
    FIELDWIDTHS = wids
    $0 = $0
}
{
    for ( i=1; i<=NF; i++ ) {
        f[tags[i]] = gensub(/^\s+|\s+$/,"","g",$i)
    }
    print f["Filesystem"], f["Available"], f["Used"]
}


    $ cat file | awk -f tst.awk | column -s $'\t' -t
Filesystem             Available  Used
/dev/mapper/xxx_crypt  100G       200G

    Substitua cat filepelo df -P -BG /que não tenho. Estou apenas tentando columnalinhar as colunas, não é necessário.

    Com essa abordagem, você pode imprimir, comparar, reordenar, fazer aritmética, etc., os valores de quaisquer colunas que desejar pelo nome. O único que tive que massagear no código foi "Montado em" para alterar o espaço para um sublinhado.

    Aqui está uma versão que funcionará em qualquer awk:

    $ cat tst.awk
BEGIN { OFS="\t" }
NR == 1 {
    sub(/Mounted on/,"Mounted_on")
    while ( match(substr($0,totWid+1),/[^ \t]+[ \t]*/) ) {
        tag = substr($0,totWid+1,RLENGTH)
        sub(/[ \t]+$/,"",tag)
        tags[++numTags] = tag
        begs[numTags] = totWid + 1
        wids[numTags] = RLENGTH
        totWid += RLENGTH
    }
}
{
    for ( i=1; i<=numTags; i++ ) {
        val = substr($0,begs[i],wids[i])
        gsub(/^[ \t]+|[ \t]+$/,"",val)
        f[tags[i]] = val
    }
    print f["Filesystem"], f["Available"], f["Used"]
}


    $ awk -f tst.awk file | column -s $'\t' -t
Filesystem             Available  Used
/dev/mapper/xxx_crypt  100G       200G
    • 1

  3. Usando Raku (anteriormente conhecido como Perl_6)

    ~$ raku -e 'my $target = "Used"; 
            my @table = lines.map: *.split(/ \h+ /).List; 
            my $col = @table.head.grep(/ $target /, :k).cache; 
            .put for @table.map: *.[ $col.flat ];'   file

    Acima está uma resposta escrita em Raku, um membro da família de linguagens de programação Perl. Resumidamente, um $escalar -sigiled é declarado e atribuído à string "Usado". Em seguida, linessão lidos, cada um mapped dentro e splitem \hespaços em branco horizontais. Normalmente, esse retorno seria realizado em uma estrutura de dados leve conhecida como no SeqRaku, mas aqui forçamos Liste salvamos os dados no @tablearray.

    Agora, para a coluna correta. Pegamos @table.heado que nos dá a linha do cabeçalho original (ou seja, linha) da tabela. Analisamos grepesses elementos para encontrar uma correspondência $targete pegamos as :kchaves, ou seja, número (s) de índice da coluna, armazenando-os em $col. Por fim, retiramos putos @a.tabledados, retornando apenas as $colcolunas desejadas.

    Entrada de amostra:

    Filesystem                  xxxxxxxxxx-blocks  Used Available Capacity Mounted on
/dev/mapper/xxx_crypt                    500G  200G      100G      xx% /

    Saída de amostra:

    Used
200G

    O OP expressou o desejo de ter um script que aceite variáveis ​​de shell. Raku possui um array associativo especial %*ENVque pode ser usado para acessar variáveis ​​​​do shell. Então abaixo pega a variável shell colNamedo ambiente (ou seja, o shell):

    ~$ env colName="Used" raku -e 'my $target = %*ENV<colName>;   \
                      my @table = lines.map: *.split(/ \h+ /).List;     \
                      my $col = @table.head.grep(/$target/, :k).cache;  \
                      .put for @table.map: *.[ $col.flat ];'   file
Used
200G

    Da mesma forma, você pode retornar duas colunas, etc., com apenas um pequeno ajuste, conforme abaixo:

    ~$ env colNames="Used Available" raku -e '   \
                      my @target = %*ENV<colNames>.split(/ \h+ /).List;  \
                      my @table = lines.map: *.split(/ \h+ /).List;      \
                      my @col = @table.head.grep(/@target/, :k);         \
                      .put for @table.map: *.[ @col.flat ];'   file
Used Available
200G 100G

    https://docs.raku.org/routine/grep
    https://raku.org

    • 0

relate perguntas