Início / unix / Perguntas / 767103
Accepted
elmo
Asked: 2024-01-17 17:18:29 +0800 CST

condições dentro de blocos de chaves

  • 772

Para fazer múltiplas passagens no mesmo arquivo de entrada, este caso simples funciona bem:

$ awk 'p==1{print $1}; p==2{print $2}; p==3{print $3}' p=1 infile p=2 infile p=3 infile

Mas falhar com essa mudança?

$ awk 'p==1{/Jan/ {print $1}}; p==2{print $2}; p==3{print $3}' p=1 infile p=2 infile p=3 infile

Não quero usar termos como:

p==1 && /Jan/ {print $1}

pois quero manter a estrutura legível do código (original).

Como posso usar termos condicionais dentro de cada colchete?

Exemplo:

$ cat infile
James   Exeter 48
Alex    Leeds  22
Jan     London 35

resultado desejado:

Jan
Exeter
Leeds
London
48
22
35
awk

2 respostas

  1. Best Answer

    O /regexp/operador é um operador que retorna 1 se $0corresponder à regexp e 0 caso contrário.

    Você pode usá-lo como print /foo/ + /bar/, por exemplo, ou if (/foo/) print "match"ou na CONDITIONparte de uma CONDITION { ACTION }instrução, mas usá-lo como parte do ACTIONin /foo/ {something}é uma sintaxe inválida, da mesma forma a == b {something}ou "whatever" {something}é inválido aí.

    Você iria querer:

    awk '
  p==1 {
    if (/Jan/) print $1
    next
  }
  p==2 {print $2; next}
  p==3 {print $3; next}
  ' p=1 infile p=2 infile p=3 infile

    Observe também as chamadas para nextevitar testes p==2e p==3se houver p==1correspondência, por exemplo.

    Aqui, você também pode simplesmente fazer:

    awk '{print $p}' p=1 infile p=2 infile p=3 infile

    Ou para imprimir apenas registros correspondentes /Jan/quando p==1:

    awk 'p != 1 || /Jan/ {print $p}' p=1 infile p=2 infile p=3 infile

    $também é um operador, você pode usar $pou $ pou $ (p * 2 - p)ou $ (field_to_print = p)que invocam o $operador para expandir para o p- ésimo campo¹.

    Com a implementação GNU de awk(também chamada gawkde ), você pode usar ARGINDwhich é incrementado para cada argumento em vez de ter que definir pvocê mesmo:

    gawk 'ARGIND != 1 || /Jan/ {print $ARGIND}' infile infile infile

    ¹ Ou o registro inteiro se p == 0

    • 4

  2. @StéphaneChazelas respondeu à sua pergunta específica, mas para ser claro - você não precisa fazer várias passagens do arquivo de entrada para fazer o que está tentando fazer, você pode fazer isso em apenas uma passagem, por exemplo:

    $ awk '/Jan/{print $1} {a=a $2 ORS; b=b $3 ORS} END{printf "%s%s", a, b}' infile
Jan
Exeter
Leeds
London
48
22
35

    ou mais geralmente para qualquer número de campos:

    $ awk '/Jan/{print $1} {for (i=2; i<=NF; i++) a[i]=a[i] $i ORS} END{for (i=2; i<=NF; i++) printf "%s", a[i]}' infile
Jan
Exeter
Leeds
London
48
22
35

    Isso só falharia se o seu arquivo de entrada fosse absolutamente enorme, grande demais para caber na memória.

    • 0

relate perguntas