Início / unix / Perguntas / 748561
Accepted
Ahmad Ismail
Asked: 2023-06-11 16:20:57 +0800 CST

Qual é a ligação de chave genérica que corresponde se nenhuma outra ligação fizer em zsh?

  • 772

Em fish shell , a ligação de chave genérica que corresponde, se nenhuma outra ligação corresponder, pode ser definida especificando uma SEQUÊNCIA da string vazia (ou seja, '' ).

Por exemplo:

bind '' self-insert

Eu verifiquei a documentação do zsh para funcionalidade semelhante, diz:

-m

Adicione o conjunto integrado de ligações de meta-chave ao mapa de teclado selecionado. Somente as chaves não vinculadas ou vinculadas à inserção automática são afetadas.

Não tenho certeza se posso usá-lo para o meu propósito.

Qual é a ligação de chave genérica que corresponde se nenhuma outra ligação fizer em zsh?

zsh

1 respostas

  1. Best Answer

    Em zsh, o widget que é invocado quando nenhum mapeamento é encontrado para uma chave (sequência de bytes enviada pelo terminal) é o undefined-keywidget que por padrão emite um bipe, mas você pode redefini-lo para algo diferente, como:

    undefined-key() {
  zle -M "${(q+)KEYS} is not bound to anything"
  zle .$WIDGET
}
zle -N undefined-key

    Ou insira os bytes brutos à esquerda do cursor com:

    undefined-key() LBUFFER+=$KEYS
zle -N undefined-key

    Não é self-insert, self-insertem mapas de teclas como emacsou viinsestá vinculado a chaves em virtude de estar vinculado a Rintervalos de bytes:

    $ bindkey | awk '$NF == "self-insert"'
" "-"~" self-insert
"\M-^@"-"\M-^?" self-insert

    São todos os valores de byte de 32 (espaço) a 255 (M-^?) Aqui, excluindo 127 ( ^?que está vinculado a backward-delete-char).

    Você pode vincular a outra coisa com:

    my-self-insert() { zle -M "You entered <$KEYS>"; zle self-insert; }
zle -N my-self-insert
for range (' -~' '\x80-\xff') bindkey -R $range my-self-insert

    Embora uma maneira talvez mais idiomática seja redefinir self-insert:

    self-insert() { zle -M "You entered <$KEYS>"; zle .$WIDGET; }

    Esteja ciente de que, para caracteres multibyte, o widget é chamado uma vez para cada byte no caractere e AFAIK, os limites do intervalo podem ser apenas bytes únicos.

    self-inserttambém funciona apenas para bytes únicos, embora você sempre possa fazer:

    my-self-insert() {
  zle -M "You entered <$KEYS>"
  repeat ${NUMERIC-1} LBUFFER+=$KEYS
}
for c ({$'\ua0'..$'\uff'}) bindkey $c my-self-insert

    Para vincular my-self-inserto caractere Unicode U+00A1 a U+00FF e fazer a auto-inserção manualmente anexando $KEYS(os bytes ou sequência de bytes enviados pelo terminal que levou à chamada do widget) para $LBUFFER(a seção do buffer de edição de linha à esquerda do cursor).

    • 1

relate perguntas