Executar se as condições em paralelo

Para serializar essas saídas (e erros), você teria que salvar pelo menos uma delas temporariamente:

#! /bin/zsh -
ret=0
umask 077 # for temp files that we recreate
if findmnt --source UUID=309689b5-ea5c-4175-84c7-192631553eab --source PARTLABEL=WDPurple8TB --mountpoint /media/ismail/WDPurple8TB --types ext4 --noheadings; then
    udisksctl unmount -b /dev/disk/by-label/WDPurple8TB &&
      udisksctl power-off -b /dev/disk/by-label/WDPurple8TB &&
      echo "Power-Off /dev/disk/by-label/WDPurple8TB"
fi & pid=$!

out==() err==()
if findmnt --source UUID=151cf7f0-461a-416f-8e44-63d799418958 --source PARTLABEL=WDPurple6TB --mountpoint /media/ismail/WDPurple6TB --types ext4 --noheadings; then
    udisksctl unmount -b /dev/disk/by-label/WDPurple6TB &&
      udisksctl power-off -b /dev/disk/by-label/WDPurple6TB &&
      echo "Power-Off /dev/disk/by-label/WDPurple6TB"
fi > $out 2> $err || ret=$?

wait $pid || ret=$?

# dump the second job's errors on stderr
cat<$err >&2

# and its output to stdout:
cat<$out

# clean up the temp files
rm -f -- $out $err

# report failure if any of any of those two jobs
exit $ret

Aqui, usando zsha =(...)forma de substituição de processo para criar arquivos temporários. Com sh ou bash, você pode usar mktempou qualquer outro comando disponível em seu sistema para criar arquivos temporários com segurança.

Estritamente, falar =(cmd)não deve ser usado assim, pois o zsh exclui o arquivo temporário assim que o comando onde ele é expandido termina. Aqui nós o recriamos mais tarde com o mesmo caminho, portanto não é estritamente seguro, pois há uma pequena janela durante a qual o arquivo pode ter sido recriado como link simbólico por um agente mal-intencionado.

Para qualquer número de desmontagens paralelas, poderíamos fatorizar um pouco as coisas. Também podemos abrir fds para os arquivos temporários a serem excluídos, para que sejam excluídos desde o início, abordando o problema acima e classificando a limpeza:

#! /bin/zsh -
zmodload zsh/system || exit
out=() err_read=() err_write=() out_read=() out_write=() pid=()
n=1 ret=0

stop_disk() {
  local uuid=$1 label=$2
  if
    findmnt --source UUID=$uuid \
            --source PARTLABEL=$label \
            --mountpoint /media/ismail/$label \
            --types ext4 \
            --noheadings
  then
    udisksctl unmount -b /dev/disk/by-label/$label &&
      udisksctl power-off -b /dev/disk/by-label/$label &&
      print -r "Power-Off /dev/disk/by-label/$label"
  fi
}

for uuid label (
  309689b5-ea5c-4175-84c7-192631553eab WDPurple8TB
  151cf7f0-461a-416f-8e44-63d799418958 WDPurple6TB
) {
  () {
     sysopen -wo cloexec -u out -- $1 &&
       sysopen -ro cloexec -u in -- $1 &&
       err_write[n]=$out err_read[n]=$in &&
       sysopen -wo cloexec -u out -- $2 &&
       sysopen -ro cloexec -u in -- $2 &&
       out_write[n]=$out out_read[n]=$in
  } =() =() || exit

  stop_disk $uuid $label >&$out_write[n] 2>&$err_write[n] &
  pid[n++]=$!
}

for (( i = 1; i <= n; i++ )) {
  wait $pid[i] || ret=$?
  cat <&$err_read[i] >&2
  cat <&$out_read[i]
}

exit $ret

(não testado)

Isso funcionaria:

#!/bin/bash

a() {
    if findmnt --source UUID=309689b5-ea5c-4175-84c7-192631553eab --source PARTLABEL=WDPurple8TB --mountpoint /media/ismail/WDPurple8TB --types ext4 --noheadings; then
        udisksctl unmount -b /dev/disk/by-label/WDPurple8TB
        udisksctl power-off -b /dev/disk/by-label/WDPurple8TB
        echo "Power-Off /dev/disk/by-label/WDPurple8TB"
    fi
}
b() {
    if findmnt --source UUID=151cf7f0-461a-416f-8e44-63d799418958 --source PARTLABEL=WDPurple6TB --mountpoint /media/ismail/WDPurple6TB --types ext4 --noheadings; then
        udisksctl unmount -b /dev/disk/by-label/WDPurple6TB
        udisksctl power-off -b /dev/disk/by-label/WDPurple6TB
        echo "Power-Off /dev/disk/by-label/WDPurple6TB"
    fi
}
export -f a b
parallel --lb ::: a b

Ou:

umnt() {
    uuid="$1"
    label="$2"
    if findmnt --source UUID="$uuid" --source PARTLABEL="$label" --mountpoint /media/ismail/"$label" --types ext4 --noheadings; then
        udisksctl unmount -b /dev/disk/by-label/"$label"
        udisksctl power-off -b /dev/disk/by-label/"$label"
        echo "Power-Off /dev/disk/by-label/$label"
    fi
}
export -f umnt
parallel --lb umnt ::: 309689b5-ea5c-4175-84c7-192631553eab 151cf7f0-461a-416f-8e44-63d799418958 :::+ WDPurple8TB WDPurple6TB