Início / unix / Perguntas / 728389
Accepted
Sophie Weigle
Asked: 2022-12-14 19:42:47 +0800 CST

Algo como `colar` mas com um alinhamento vertical após um delimitador?

  • 772

Desejo colar dois arquivos juntos, mas com alinhamento vertical após uma linha delimitadora de seção ::. Aqui está o que quero dizer.

Conteúdo de file1:

Apple
Banana
Carrot
::
Durian

Conteúdo de file2:

Energy
Flight
::
Gravity
Heartbreak

Saída desejada:

Apple Energy
Banana Flight
Carrot 
::
Durian Gravity
 Heartbreak

Até agora eu sei que quasepaste fará o que eu quero (sem o belo alinhamento vertical); outra opção é dividir em vários arquivos e , em seguida, concatenar os resultados, mas quero evitar isso se puder. Como posso fazer isso?file1file2

Não preciso estritamente de uma solução que use paste. Qualquer coisa que funcione funciona!

text-processing

2 respostas

  1. Best Answer

    Usando qualquer awk:

    $ cat tst.awk
BEGIN {
    blockSep = "::"
}
FNR == 1 {
    numBlocks[++fileNr] = 0
}
(FNR == 1) || ($0 == blockSep) {
    numLines[fileNr,++numBlocks[fileNr]] = 0
}
$0 != blockSep {
    vals[fileNr,numBlocks[fileNr],++numLines[fileNr,numBlocks[fileNr]]] = $0
}
END {
    maxBlocks = ( numBlocks[1] > numBlocks[2] ? numBlocks[1] : numBlocks[2] )
    for ( blockNr=1; blockNr<=maxBlocks; blockNr++ ) {
        maxLines = ( numLines[1,blockNr] > numLines[2,blockNr] ? numLines[1,blockNr] : numLines[2,blockNr] )
        for ( lineNr=1; lineNr<=maxLines; lineNr++ ) {
            print vals[1,blockNr,lineNr], vals[2,blockNr,lineNr]
        }
        if ( blockNr < maxBlocks ) {
            print blockSep
        }
    }
}


    $ awk -f tst.awk file1 file2
Apple Energy
Banana Flight
Carrot
::
Durian Gravity
 Heartbreak
    • 2

  2. Esta é uma solução extremamente hackeada que funciona com seus dados de exemplo porque os dois arquivos têm apenas a ::linha em comum e porque os arquivos contêm apenas palavras simples (sem espaços). Eu o consideraria, portanto, extremamente frágil e nada genérico.

    Ele analisa a saída lado a lado diff, então é isso diffque faz o alinhamento vertical.

    $ diff -y file1 file2 | awk -v OFS='\t' 'NF == 3 { print $1, $3; next } $2 == "<" { print $1; next } $1 == ">" { print "", $2; next } { print $1 }'
Apple   Energy
Banana  Flight
Carrot
::
Durian  Gravity
        Heartbreak

    O awkcódigo que analisa a diff -ysaída produz partes selecionadas de cada linha, dependendo do número de campos e do conteúdo de certas partes dos dados.

    • 1

relate perguntas