Início / unix / Perguntas / 702967
Accepted
Sollosa
Asked: 2022-05-18 16:50:28 +0800 CST

script awk substitua valor por incremento com if

  • 772

Eu tenho um arquivo delimitado por pipe

d1000|1000
d1001|100
d1002|10
d1003|1
d1004|
d1005|

Eu quero modificar $ 2 se o comprimento for menor que 4 dígitos e também manter os espaços vazios como estão

então tentando fazer isso via script awk

BEGIN { FS="|"; OFS="\t" }

{
n=1100
{ if (length($2)!=4 && length($2)>0) {$2=++n}};

print $1, $2
}

mas está imprimindo o mesmo número repetidamente

d1000   1000
d1001   1101
d1002   1101
d1003   1101
d1004
d1005

enquanto a saída desejada

d1000   1000
d1001   1101
d1002   1102
d1003   1103
d1004
d1005

EDIT: aqui está o código acima formatado de forma legível por gawk -o-:

BEGIN {
        FS = "|"
        OFS = "\t"
}

{
        n = 1100
        if (length($2) != 4 && length($2) > 0) {
                $2 = ++n
        }
        print $1, $2
}
awk text-processing

2 respostas

  1. Best Answer

    O erro pode ser óbvio com recuo mais consistente:

    BEGIN { FS="|"; OFS="\t" }
{
  n=1100
  {
    if (length($2)!=4 && length($2)>0) {
      $2=++n
    }
  };
  print $1, $2
}

    Tudo dentro das chaves externas é executado, incondicionalmente, para cada registro - então o valor de né redefinido a cada linha.

    Você deve mover a inicialização de npara o BEGINbloco:

    BEGIN { FS="|"; OFS="\t"; n=1100 }
{
  {
    if (length($2)!=4 && length($2)>0) {
      $2=++n
    }
  };
  print $1, $2
}

    ou (mais idiomaticamente)

    BEGIN { FS="|"; OFS="\t"; n=1100 }
(length($2)!=4 && length($2)>0) {
  $2=++n
}
{
  print $1, $2
}
    • 4

  2. Proponho esta solução:

    $ awk -F'|' -v OFS='\t' '$2 ~ /^[0-9]{1,3}$/ { $2 = 1100 +(++c) } { print $1,$2 }' file 
d1000   1000
d1001   1101
d1002   1102
d1003   1103
d1004
d1005
    • 1

relate perguntas