Eu usaria uma função wrapper: você pode adicionar isso ao seu .bashrc (não testado)

mv () {
    case $1 in
        -*i*) # ok, used `mv -i ...`: invoke the mv command, passing all args
            command mv "$@"
            ;;
        *)
            echo "hey, use 'mv -i'" >&2
            false
            ;;
    esac
}

A maneira mais fácil é criar um alias.

alias mv="mv -i"

Mais complicado, mas mais personalizável, seria criar um mvscript de shell, colocá-lo no /bin, e o mvmovimento real para /sbinou qualquer outro diretório 'secreto'. O script de substituição fará avisos e chamará o original mvpelo caminho completo.

Se você quiser se salvar completamente mv- renomeie ou exclua a ferramenta.

Sim, outros scripts podem falhar devido a tais modificações. Nesse caso, você pode entrar nesses scripts e corrigi-los, substituindo mvpor um/secret/path/mv

Outra maneira - crie um usuário especial para a vida cotidiana. Crie para ele (geralmente em $HOME/bin) uma cópia do real /bincom exclusão de ferramentas perigosas. Defina um PATH para esse usuário diário que usará /home/everyday/binem vez de /bin.
Se algum aplicativo agora exigir ferramentas "perigosas" - esse aplicativo não é para o usuário "cotidiano" - mude para um usuário com mais privilégios.

Embora a abordagem de @glennJackman com um wrapper que verifica se os primeiros argumentos começam com -e contém iseja boa o suficiente na maioria dos casos comuns, há alguns casos em que ela falha:

• Fica no caminho de mv --help(não --versionque contém -i).
• Ele falha em detectar o -iin mv -v -i a b(ou o mv a b -ique o GNU mvpermite quando não há nenhum POSIXLY_CORRECTno ambiente).
• Não cobre GNU 's mv --interactive// ...mv --inmv --i
• Falta o que falta -iem mv --no-target-dir a bou mv -Tdir file...

Para um wrapper cobrir todos esses casos, precisaríamos que ele analisasse suas opções da mesma maneira mv. Não são duas implementações que analisam suas opções da mesma maneira. Você encontrará até diferenças entre as versões das mesmas mvimplementações.

A implementação do GNU mv(e a maioria dos utilitários) usará getopt_long()para analisar suas opções.

Se seu wrapper pudesse chamar getopt_long()com os mesmos argumentos, seríamos classificados. O que deixa dois problemas:

1. Precisamos encontrar uma interface para getopt_long()o shell
2. precisamos descobrir que esses argumentos mvpassam paragetopt_long()

Se você estiver em um sistema GNU/Linux, existem maneiras possíveis.

Embora não haja shell CLI getopt_long()na caixa de ferramentas GNU, há uma em util-linux: seu getoptutilitário quando usado com -oe -l.

No GNU/Linux, os utilitários GNU invocarão a getopt_long()função da libc como será a GNU libc, então você pode usar ltracequais chamadas de biblioteca de rastreamentos para ver qual getopt_long()chamada mvfaz para analisar opções.

$ ltrace -e getopt_long mv -:
mv->getopt_long(2, 0x7ffcf7febd68, "bfint:uvS:TZ", 0x5650dd02fb20, nilmv: invalid option -- ':'
)                           = 63
Try 'mv --help' for more information.
+++ exited (status 1) +++

(onde -:é garantido ser uma opção falsa)

Não é bom o suficiente, pois vemos apenas as opções curtas. No entanto, é possível configurar ltracepara decodificar o long_optionsargumento e até ocultar os parâmetros que não nos importam.

Como prova de conceito, aqui está um script zsh que produziria o shcódigo compatível para uma função wrapper que verifica se o -i/ --interactive(ou --help/ --version) ou suas abreviações antes de chamar mv:

#! /bin/zsh -
set -o extendedglob
die() {
  print -ru2 -- "$@"
  exit 1
}

for cmd do
  getopt_long_call=$(
    ltrace -F/dev/fd/3 3<<'EOF' -o/dev/fd/4 4>&1 > /dev/null 2>&1 -s 999 -A999 -e getopt_long "$cmd" -:
int getopt_long(hide(int),hide(addr),string,array(struct(string,int,hide(int*),hide(int)),zero),hide(int*));
EOF
  )
  getopt_long_call=${getopt_long_call%%$'\n'*}

  [[ $getopt_long_call = (#b)[^\"]#'getopt_long("'([^\"]#)'", [ '(*)' ]) = '<-> ]] ||
    die "Can't determine what getopt_long call $cmd does"

  short_opts=() long_opts=()
  : ${match[1]//(#m)?:#/${short_opts[1+$#short_opts]::=$MATCH}}
  : ${match[2]//(#b)'{ "'([^\"]#)'", '(<->)' }'/${long_opts[1+$#long_opts]::=$match[1]${(l($match[2])(:))}}}
  opts_with_args=(-${(M)^short_opts:#*:} --${(M)^long_opts:#*:})
  opts_with_args=(${opts_with_args%%:#})

  print -r -- $cmd'() {
  (
    opt=$(getopt -qo '${(j[]qq)short_opts}' '${(qq)long_opts/#/-l}' -- "$@") || exit 0
    eval "set -- $opt"
    while [ "$#" -gt 0 ]; do
      case $1 in
        (-i | --interactive | --version | --help) exit;;
        (--) printf >&2 "%s\n" "Please run '$cmd' with -i/--interactive"
             exit 1;;
        ('${(j[ | ])${(qq)opts_with_args}}') shift;;
      esac
      shift
    done
    echo >&2 "Oops. Something when wrong"
    exit 1
  ) || return
  command '$cmd' "$@"
}'
done

Por exemplo, no meu sistema, as that-script mv rmsaídas:

mv() {
  (
    opt=$(getopt -qo 'bfint:uvS:TZ' '-lbackup::' '-lcontext' '-lforce' '-linteractive' '-lno-clobber' '-lno-target-directory' '-lstrip-trailing-slashes' '-lsuffix:' '-ltarget-directory:' '-lupdate' '-lverbose' '-lhelp' '-lversion' -- "$@") || exit 0
    eval "set -- $opt"
    while [ "$#" -gt 0 ]; do
      case $1 in
    (-i | --interactive | --version | --help) exit;;
    (--) printf >&2 "%s\n" "Please run mv with -i/--interactive"
         exit 1;;
    ('-t' | '-S' | '--backup' | '--suffix' | '--target-directory') shift;;
      esac
      shift
    done
    echo >&2 "Oops. Something when wrong"
    exit 1
  ) || return
  command mv "$@"
}
rm() {
  (
    opt=$(getopt -qo 'dfirvIR' '-lforce' '-linteractive::' '-lone-file-system' '-lno-preserve-root' '-lpreserve-root::' '-l-presume-input-tty' '-lrecursive' '-ldir' '-lverbose' '-lhelp' '-lversion' -- "$@") || exit 0
    eval "set -- $opt"
    while [ "$#" -gt 0 ]; do
      case $1 in
    (-i | --interactive | --version | --help) exit;;
    (--) printf >&2 "%s\n" "Please run rm with -i/--interactive"
         exit 1;;
    ('--interactive' | '--preserve-root') shift;;
      esac
      shift
    done
    echo >&2 "Oops. Something when wrong"
    exit 1
  ) || return
  command rm "$@"
}

Você faria:

eval "$(that-script mv rm)"

Na configuração do modo interativo do seu shell ( ~/.zshrc, ~/.bashrc...).

Para definir esses wrapper. E depois:

$ rm a -i
rm: remove regular file 'a'? n
$ rm a --int
rm: remove regular file 'a'? n
$ mv --version
mv (GNU coreutils) 8.32
Copyright (C) 2020 Free Software Foundation, Inc.
License GPLv3+: GNU GPL version 3 or later <https://gnu.org/licenses/gpl.html>.
This is free software: you are free to change and redistribute it.
There is NO WARRANTY, to the extent permitted by law.

Written by Mike Parker, David MacKenzie, and Jim Meyering.
$ POSIXLY_CORRECT=1 rm a -i
Please run rm with -i/--interactive