Início / unix / Perguntas / 697806
Accepted
acjca2
Asked: 2022-04-04 03:08:18 +0800 CST

Printf formatando uma variável ZSH sem bifurcação?

  • 772

Para meu prompt personalizado powerlevel10k, atualmente tenho essa função para exibir os segundos desde a época, separados por vírgula. Eu o mostro na hora atual para que eu sempre tenha uma dica para lembrar aproximadamente qual é a hora da época atual.

function prompt_epoch() {
  MYEPOCH=$(/bin/date +%s | sed ':a;s/\B[0-9]\{3\}\>/,&/;ta')
  p10k segment -f 66 -t ${MYEPOCH}
}

Meu prompt está assim: captura de tela de exemplo de prompt

Me disseram que posso fazer isso sem os processos bifurcados usando estes comandos:

$ zmodload -F zsh/datetime p:EPOCHSECONDS
$ printf "%'d" $EPOCHSECONDS
1,648,943,504

Mas não sei como fazer isso sem a bifurcação. Eu sei adicionar a zmodloadlinha no meu ~/.zshrcantes que meu powerlevel10k seja originado, mas a formatação ${EPOCHSECONDS}não é algo que eu saiba fazer sem um fork.

Se eu estivesse fazendo do jeito que eu sei, isso é o que eu faria:

function prompt_epoch() {
  MYEPOCH=$(printf "%'d" ${EPOCHSECONDS})
  p10k segment -f 66 -t ${MYEPOCH}
}

Mas até onde eu entendo, isso ainda está bifurcando um processo toda vez que o prompt é chamado, correto? Estou entendendo mal o conselho dado porque não acho que posso ver uma maneira de obter os últimos segundos da época sem executar algum tipo de processo, que requer um fork, correto?

zsh printf

2 respostas

  1. Best Answer

    O printfutilitário em ambos bashe zshtem uma -vopção que permite "imprimir em uma variável":

    printf -v MYEPOCH "%'d" ${EPOCHSECONDS}

    O resultado real do comando acima pode depender da localidade atual.

    • 7

  2. FWIW, você também pode fazer:

    zmodload zsh/datetime
set -o histsubstpattern -o promptsubst -o extendedglob
RPS1='$EPOCHSECONDS:fs/%(#b)([^,])([^,](#c3)(|,*))/$match[1],$match[2]'

    Para obter algo como 1,648,989,768no prompt certo sem bifurcar um processo nem depender da localidade para o valor do separador de milhares.

    ${param:fs/left/right}usa o modificador de históricos substituto como em csh, enquanto aquele o repete enquanto muda algo, alcançando algo semelhante à sua abordagem GNU.fsed

    Com a histsubstpatternopção habilitada, leftpode ser um padrão, então $param:s/left/rightse comporta como ksh93, ${param/pattern/replacement}exceto que podemos combiná-lo com aquele fmodificador que o torna mais útil aqui.

    Como com ksh93's ${param/pattern/replacement}, o padrão pode ser precedido por %para corresponder apenas no final do assunto. Com extendedglob, podemos habilitar back-references com (#b)ou usar (#c3)para combinar 3 do átomo anterior como ERE's {3}.

    Observe que ao lado $EPOCHSECONDS(para o qual você precisa carregar o zsh/datetimemódulo), o tempo de época também pode ser obtido com a %D{%s}expansão do prompt. Para poder aplicar um modificador nele, você teria que expandi-lo como parte da expansão do parâmetro. Isso pode ser feito com o %sinalizador de expansão do parâmetro:

    set -o histsubstpattern -o promptsubst -o extendedglob
RPS1='${${(%):-"%D{%s}"}:fs/%(#b)([^,])([^,](#c3)(|,*))/$match[1],$match[2]}'
    • 3

relate perguntas