Início / unix / Perguntas / 693084
Accepted
iconoclast
Asked: 2022-03-06 15:36:12 +0800 CST

Como posso fazer o zsh globbing ignorar arquivos como .DS_Store

  • 772

Na maioria das vezes, gosto da combinação de (por um lado) executar zsh em uma variante BSD no iTerm, mas (por outro lado) ter a experiência do macOS disponível para aplicativos que não são executados ou não geram tanto sentido para executar em um terminal.

Mas uma coisa que me deixa louco são os .DS_Storearquivos horríveis que o macOS despeja em todo o lugar.

Posso configurar o zsh para que, se eu digitar (por exemplo) nvim *tab, o *seja expandido sem incluir nenhum arquivo que eu queira evitar? (Isso pode incluir .DS_Store, Icon?e potencialmente outros que não consigo pensar agora.)

Não estou perguntando como posso construir um padrão no local que exclua determinados arquivos (exemplos aqui , aqui e aqui ), mas como posso fazer com que todos os globs sempre excluam determinados arquivos.

zsh wildcards

1 respostas

  1. Best Answer

    Você não pode personalizar o globbing, exceto pela dot_globopção. Esse é um dos poucos recursos que existe no ATT ksh e no bash, mas não no zsh. Assim echo *sempre mostrará Icon1.

    Você pode ignorar padrões na conclusão, mas fica complicado quando curingas estão envolvidos. Vamos começar com algo simples: a conclusão não envolve curingas. Com o seguinte .zshrcarquivo , como .DS_Storee Icon1não será oferecido para conclusão, a menos que não haja correspondências de outra forma.

    autoload -zU compinit
compinit
zstyle ':completion::complete:*:*:files' ignored-patterns '.DS_Store' 'Icon?'
zstyle ':completion::complete:*:*:globbed-files' ignored-patterns '.DS_Store' 'Icon?'
zstyle ':completion::complete:rm:*:globbed-files' ignored-patterns

    Explicação: Eu defino estilos de conclusão :

    • Aplicam-se sempre que fizer a conclusão.
    • Eles se aplicam quando a “função” está vazia (isso exclui alguns widgets especiais).
    • Aplicam-se ao fazer o preenchimento normal ( _complete), em oposição, por exemplo, à correção ou _ingore.
    • Eles se aplicam a qualquer comando, exceto rm. Para o rmcomando, o snippet acima define uma lista de ignorados vazia, que substitui o padrão.
    • Eles se aplicam a qualquer posição na linha de comando.
    • Eles se aplicam ao coletar nomes de arquivos (por meio da tag _filesou da tag _globbed-files).

    Esses estilos não se aplicam à expansão curinga. Por padrão, a expansão curinga em Tabignora o código de conclusão. Para fazê-lo usar o código de conclusão, especificamente o _expandcompleter , você precisa vincular Tabe complete-wordusar o _expandcompleter, que usa a expansionstag.

    autoload -zU compinit
compinit
bindkey '^I' complete-word
zstyle ':completion:::::' completer _expand _complete _ignored
zstyle ':completion::expand:*:*:expansions' ignored-patterns '.DS_Store' 'Icon?'
zstyle ':completion::expand:*:*:all-expansions' ignored-patterns '.DS_Store' 'Icon?'

    Com isso , .zshrcem um diretório contendo .DOH, .DS_Storeand .zshrc, echo .*Tabpercorre .DOH, .zshrce .DOH .DS_Store .zshrc. .*Graças ao ignored-patternsestilo na expansionstag, .DS_Storeé ignorado ao percorrer as expansões individuais. Há uma all-expansionstag que se aplica ao expandir para a lista de correspondências, mas infelizmente não suporta ignored-patterns. (Na verdade, meio que faz, mas de uma maneira inútil: pode ser usado para remover toda a lista de correspondências, não para remover elementos individuais dela.)

    A única maneira que encontrei para filtrar correspondências da lista de todas as expansões é corrigir a _expandfunção .

    diff --git a/Completion/Base/Completer/_expand b/Completion/Base/Completer/_expand
index e5e4f9b39..df6f55a7d 100644
--- a/Completion/Base/Completer/_expand
+++ b/Completion/Base/Completer/_expand
@@ -107,7 +107,13 @@ subd=("$exp[@]")
 integer done_quote
 local -a orig_exp=( $exp )
 if [[ "$force" = *g* ]] || zstyle -T ":completion:${curcontext}:" glob; then
-  eval 'exp=( ${~exp//(#b)\\([     \"'"\'"'
+  local -a exps igns
+  exps=($~exp)
+  zstyle -a ":completion:${curcontext}:all-expansions" ignored-patterns igns
+  if (($#igns)); then
+    eval "exps=(\${exps:#(${(j:|:)igns})})"
+  fi
+  eval 'exp=( ${exps//(#b)\\([     \"'"\'"'
 ])/$match[1]} ); exp=( ${(q)exp} )' 2>/dev/null && (( $#exp )) && done_quote=1
 fi
 # If the globbing failed, or we didn't try globbing, we'll do

    Com este patch e o .zshrcacima, a all-expansionstag faz com .DS_Storeque seja ignorada por echo .* Tab.

    Cuidado que eu testei apenas minimamente este patch. Pode quebrar outras coisas. Pode não funcionar em algumas configurações. Pode não citar nomes de arquivo corretamente.

    • 1

relate perguntas