Início / unix / Perguntas / 691170
Accepted
Tarun
Asked: 2022-02-18 23:24:04 +0800 CST

Calcular o salário médio do departamento a partir da string de entrada

  • 772

Se o usuário inserir os detalhes dos funcionários como string e quisermos que a saída exiba o salário médio do departamento e a saída deve estar na mesma ordem em que aparecem na string de entrada.

Por exemplo, string de entrada:

EMP101:Jack:HR:6000#EMP102:Jill:Management:10000#EMP103:Russell:Testing:10000#EMP104:Monica:HR:15000#EMP105:John:Management:25000#EMP106:Ram:Testing:8000#EMP107:Tan:HR:15000#EMP108:Harry:Management:10000

Cadeia de saída:

HR:12000#Management:15000#Testing:9000

Tentei abaixo o código:

echo "EMP101:Jack:HR:6000#EMP102:Jill:Management:10000#EMP103:Russell:Testing:10000#EMP104:Monica:HR:15000#EMP105:John:Management:25000#EMP106:Ram:Testing:8000#EMP107:Tan:HR:15000#EMP108:Harry:Management:10000" \
| awk 'BEGIN{RS="#"; OFS=FS=":"} {gsub(/"\n$/,"",$5); print $3,$4}' \
| awk -F ":" '{a[$1] += $2} {b[$1] += 1} END{for (i in a) print i, a[i]/b[i]}' \
| tr " " ":" \
| tr "\n" "#";

obteve a saída como:

:0#Testing:9000#Management:15000#HR:12000

Isso não é o que eu quero e também não estou entendendo por que :0#está sendo adicionado no início da string. Alguém poderia me dizer como conseguir isso no script de shell

awk text-processing

4 respostas

  1. Usando any awke preservando a ordem:

    awk 'BEGIN{ RS="#"; FS=OFS=":" }
   { ($3 in dept)?"":ordrDept[++i]=$3; dept[$3]+=$4; seenDept[$3]++; }
END{ for(o=1; o<=i; o++)
         printf "%s%d%s", ordrDept[o] OFS, 
                          dept[ordrDept[o]]/seenDept[ordrDept[o]], 
                          (i==o)?ORS:RS
}' infile

    Resultado:

    HR:12000#Management:15000#Testing:9000

    Usamos a ordrDeptmatriz para lembrar a ordem de cada departamento pela ordem em que foram vistos.
    Usamos a dept matriz para resumir o salário total de cada departamento.
    Usamos o seenDeptarray para lembrar quantas vezes eles foram vistos.

    no END{...}bloco, e iseria o número máximo de departamentos existentes que visitamos em ordrDept[++i]=$3, então estamos imprimindo-os na ordem que visitamos primeiro por ordrDept[o], depois o cálculo do salário médio total/countpor departamento e com (i==o)?ORS:RSisso estamos controlando os separadores.

    Uma implementação alternativa da abordagem acima com nomes de variáveis ​​mais significativos seria (graças a @EdMorton):

    BEGIN {
    RS = "#"
    FS = OFS = ":"
}
!($3 in depts2sals) {
    depts[++numDepts] = $3
}
{
    depts2sals[$3] += $4
    depts2cnts[$3]++
}
END {
    for (deptNr=1; deptNr<=numDepts; deptNr++) {
        dept = depts[deptNr]
        sal = depts2sals[dept]
        cnt = depts2cnts[dept]
        avg = sal / cnt
        printf "%s%s%s", dept OFS, avg, (deptNr<numDepts ? RS : ORS)
    }
}
    • 2
  2. Best Answer

    Outra variação de um tema

    echo 'EMP101:Jack:HR:6000#EMP102:Jill:Management:10000#EMP103:Russell:Testing:10000#EMP104:Monica:HR:15000#EMP105:John:Management:25000#EMP106:Ram:Testing:8000#EMP107:Tan:HR:15000#EMP108:Harry:Management:10000' |
    awk -F'#' '
        # Split into lines at "#"
        {
            for(f=1; f<=NF; f++) {
                print $f;
            }
        }
    ' |
    awk -F: '
        # Record department if unknown. Keep running total and count
        {
            if (!(sum[$3]+0)) { pos[idx++]=$3 };
            sum[$3]+=$4;
            count[$3]++;
        }
        # Output department in order of recording, and calculate average
        END {
            for (idx in pos) {
                dept=pos[idx];
                printf "#%s:%d", dept, sum[dept]/count[dept];
            };
            printf "\n";
        }
    ' |
    cut -c2-

    Resultado

    HR:12000#Management:15000#Testing:9000
    • 1

  3. O :0#é devido a uma linha adicional, à direita, vazia em sua entrada/arquivo. Sua tentativa de remover isso falha porque você forneceu o padrão errado gsub(...), bem como um campo que não existe. RSCorrija isso ou use uma variável estendida . Como awkpor si só é bastante poderoso, não há necessidade de executar essa pilha de tubos; fazê-lo em um awksó.

    Tentar

    awk 'BEGIN{ORS="#"; RS="[#\n]"; OFS=FS=":"} {SUM[$3]+=$4;CNT[$3]++} END{for (s in SUM) print s, SUM[s]/CNT[s]} ' file3
Management:15000#Testing:9000#HR:12000#

    A remoção do ORS à direita fica como exercício para o leitor.

    • 0

  4. Aqui está um método usando perl .

    echo 'your-string' |
perl -lnse 'while ( /:([^:#]+):(\d+)(?=#|$)/g )
{
  my @A = ($2,1);
  exists $s{$1} or $D[@D]=$1;
  $_->{$1} += shift(@A) for \(%s,%k);
}
print map { join(":", $_, $s{$_}/$k{$_}) } @D;
' -- -,=\#

    As estruturas de dados envolvidas:

    • hash %s digitado no departamento contém a soma correspondente dos salários dos funcionários do mesmo departamento.
    • hash %k digitado no departamento contém o número de funcionários nesse departamento.
    • array @D contém o departamento na ordem em que foram encontrados, sem repetir.

    Abaixo está um método retirado de sua tentativa

    echo 'your_string' |
tr '#' '\n' |
awk -F: '{print $3, NR, $4}' |
sort -k1 -k2n |
awk '
prev != $1 {
  if (NR > 1) print prev, sum/knt
  knt=sum=0;prev=$1
}
{ knt++; sum += $3 }
END { ORS=RS; print prev, sum/knt }
' OFS=: ORS=\#

    A abordagem GNU sed é fornecida. A ideia é juntar o mesmo departamento e separar os salários dentro do mesmo departamento.

    ## dc code to compute average of a list of numbers
avg='[+z1<a]sa\3zsnlaxln/f'

echo 'your_string' |
sed -Ee '
  y/#/\n/
  s/^([^:]*:){2}//Mg;ta
  :a
  s/((^|\n)([^:]+):([0-9]+( [0-9]+)?))(\n(.*\n)?)\3:([0-9]+)(\n|$)/\1 \8\6/
  ta
  :b'"
  s#^((.*\n)?[^:]+:)([0-9]+( [0-9]+)+)((\n.*)?)#printf %s '\\1' \"\$(echo '$avg'|dc)\" '\\5'#e
  tb
  y/\n/#/
"
    • 0

relate perguntas