awk extrair números de uma string

Com GNU awk para multi-char RS e RT:

$ echo "blah foo123bar234blah" |
    awk -v RS='[0-9]+' '$0=RT'
123
234

Com qualquer awk (e mantendo o regexp original em vez de negá-lo, pois isso só é fácil com uma expressão de colchetes simples e não uma abordagem geral robusta):

$ echo "blah foo123bar234blah" |
    awk -v FS='\n' '{gsub(/[0-9]+/,FS"&"FS); for (i=2;i<=NF;i+=2) print $i}'
123
234

ou:

$ echo "blah foo123bar234blah" |
    awk '{ while (match($0,/[0-9]+/) ) {print substr($0,RSTART,RLENGTH); $0=substr($0,RSTART+RLENGTH)} }'
123
234

A match()função executa uma única correspondência de sua expressão regular. Para encontrar cada execução de dígitos usando correspondência de expressão regular com match()em GNU awk, você precisa fazer um loop.

{
    str = $0
    while (match(str,"[0-9]+",a)) {
        print a[0]
        str = substr(str,RSTART+RLENGTH)
    }
}

Estamos interessados ​​apenas a[0]aqui, pois não usamos parênteses em nossa expressão regular. Não usamos parênteses em nossa expressão porque não precisamos deles. Possivelmente precisaríamos de parênteses se quiséssemos combinar um número conhecido de inteiros com uma única expressão (por exemplo ([0-9]+)[^0-9]+([0-9]+), , etc.), mas neste exercício não sabemos realmente quantos inteiros podem existir.

Ou, com padrão awk,

{
    str = $0
    while (match(str,"[0-9]+")) {
        print substr(str,RSTART,RLENGTH)
        str = substr(str,RSTART+RLENGTH)
    }
}

Isso corresponde a execuções de dígitos consecutivos na string em str. Para cada correspondência, a string correspondente é impressa e a parte strque não é mais interessante é removida usando substr().

Teste:

$ echo 'blah foo123bar234blah' | gawk '{ str = $0; while (match(str,"[0-9]+",a)) { print a[0]; str = substr(str,RSTART+RLENGTH) } }'
123
234

Você pode usar a gsub()função de awke transformar todas as ocorrências de "substrings que não consistem em dígitos" em espaços simples e, em seguida, usar a split()função para dividir a string resultante no espaço em branco. Isso se comporta como divisão de campo na FSvariável padrão e descarta "campos vazios" à esquerda e à direita:

awk '{gsub(/[^0-9]+/," ");n=split($0,a);for (i=1;i<=n;i++) print a[i]}'

Então, para o seu exemplo:

~$ echo "blah foo123bar234blah" | awk '{gsub(/[^0-9]+/," ");n=split($0,a);for (i=1;i<=n;i++) print a[i]}'
123
234

Para extrair 0-9dígitos em inglês, usando GNU awk para o FPAT:

awk -v FPAT='[0-9]+' -v OFS='\n' '$1=$1""'

ou com qualquer awk:

awk -F'[^0-9]+' '{ for(i=1; i<=NF; i++) if($i+0==$i) print $i }' infile

ou especificamente usando a função match() (nenhum benefício BTW, pois sabemos que filtramos apenas dígitos em [^0-9]+, então todo o resto são apenas dígitos, mas sim, para evitar a impressão de campos vazios, é útil, mas não melhor do $i+0==$ique acima):

awk -F'[^0-9]+' '{
    for(i=1; i<=NF; i++) {
        if (match($i, /[0-9]+/)) print $i
    }
}' infile

Se você realmente deseja apenas extrair números (números naturais e zero no exemplo a seguir!), você pode definir qualquer outra coisa como separadores de campo:

awk 'BEGIN {FS="[^0-9]+"}
     {printf $1 ; for (i=2 ; i<=NF ; i++) { printf " "$i} ; printf "\n"}'

(adicionada alguma formatação para retornar entradas separadas por espaço para uma linha por registro)

E também outra opção usando GNU awkpara patsplit():

echo "blah foo123bar234blah" | awk 'patsplit($0, a, /[[:digit:]]+/) { for (i in a) printf "%d\n", a[i]}'
123
234

por que torná-lo tão complexo com todo esse FPAT e patsplit e while(match()) -

apenas isto basta:

 echo 'blah foo123bar234blah' \
 \
 | mawk2 'BEGIN { FS="[^0-9]+"; OFS=ORS; ORS="" } NF=NF'

123
234