Como montar automaticamente um ponto de montagem de pré-requisito para o que estou montando?

Se você quiser que o subdiretório "principal" do FS LABEL=XYZseja montado em /newplace, sem precisar que todo o FS seja montado em /mypath, você pode adicionar uma linha como:

LABEL=XYZ /newplace subdir subdir=main,srctype=vfat,noauto,... 0 0

E crie o /sbin/mount.subdirauxiliar (chamado por mount /newplace, não deve ser chamado diretamente) como um script como:

#! /bin/zsh -p
(( EUID == 0 )) || exec sudo -- "$0" "$@"
PATH=/bin:/sbin:/usr/bin:/usr/sbin

# mount -t subdir -o subdir=foo -o otheroption source /dest calls us
# as mount.subdir source /dest -o rw,subdir=foo,otheroption
dev=${1?} dest=${2?} opts=( ${(s[,])4?} )

# extract mandatory subdir option
(( i = $opts[(I)subdir=*] )) || exit
subdir=${opts[i]#*=}
opts[i]=()

# extract optional srctype option
if (( i = $opts[(I)srctype=*] )); then
  type=(-t "$opts[i]")
  opts[i]=()
else
  type=()
fi

tmpdir=$(mktemp -d) || exit

mounted()true
if
  mount "$type[@]" -o "${(j[,])opts}" -- "$dev" "$tmpdir"
then
  mount --bind -- "$tmpdir/$subdir" "$dest" || mounted()false
  umount -- "$tmpdir"
fi && rmdir -- "$tmpdir" && mounted

Que monta todo o FS em um tmpdir, monta o subdiretório no destino e depois desmonta e remove o tmpdir.

Se, conforme esclarecido em sua edição posterior, você deseja que ambos /newplacee /mypathsejam montados e /mypathnão seja apenas uma etapa intermediária para o objetivo final de ter um subdiretório do FS montado em /myplace, você pode adotar uma abordagem semelhante, e isso se torna mais fácil à medida que você só precisa do ajudante para montar o(s) FS(s) de pré-requisito:

LABEL=XYZ /mypath vfat noauto,[...]
/myplace/main /newplace prereq prereq=/myplace,noauto,... 0 0

E crie o /sbin/mount.prereqauxiliar como um script como:

#! /bin/zsh -p
(( EUID == 0 )) || exec sudo -- "$0" "$@"
PATH=/bin:/sbin:/usr/bin:/usr/sbin

src=${1?} dst=${2?} opts=( ${(s[,])4?} )

# extract prereq options
for prereq in ${(M)opts:#prereq=*}; do
  prereq=${prereq#*=}
  mountpoint -q -- $prereq ||
    mount -- $prereq ||
    exit
done
opts=(${opts:#prereq=*})

exec mount --bind -o "${(j[,])opts}" -- "$src" "$dst"

Observe que /mypathnão é desmontado automaticamente depois de /newplacedesmontado.

O mesmo com a sintaxe do shell POSIX (portanto, deve funcionar em bash) pode ser assim:

#! /bin/sh -
[ "$(id -u)" -eq 0 ] || exec sudo -- "$0" "$@"
PATH=/bin:/sbin:/usr/bin:/usr/sbin

src="${1?}" dst="${2?}"

set -o noglob
IFS=,
set -- ${4?}

# extract prereq options
for opt do
  case $opt in
    (prereq=*)
      prereq=${opt#*=}
      mountpoint -q -- "$prereq" ||
        mount -- "$prereq" ||
        exit
      ;;
    (*)
      set -- "$@" "$opt"
  esac
  shift
done
opts="$*"

exec mount --bind -o "$opts" -- "$src" "$dst"

(não testado).

Se você não pode editar seu script, você pode instrumentá-lo. Por exemplo, se estiver escrito em bash, chame-o como:

bash -c '
  mount() {
    if [[ $1 = "/newplace" ]]; then
      command mount /mypath || return
    fi
    command mount "$@"
  }
  export -f mount
  exec "$0" "$@"' your-script its args

Ou se estiver escrito em zsh, adicione a ~/.zshenv(ou /some/dir/.zshenve defina ZDOTDIR=/some/dirpara esse script):

if [[ $ZSH_SCRIPT:P = /path/to/your-script ]]; then
  mount() {
    if [[ $1 = /newplace ]]; then
      command mount /mypath || return
    fi
    command mount "$@"
  }
fi

Ou para qualquer shell, adicione um mountscript /some/dirque faça o mesmo:

#! /bin/sh -
if [ "$1" = /newplace ]; then
  /bin/mount /mypath || exit
fi
exec /bin/mount "$@"

E chame seu script como:

PATH="/some/dir:$PATH" your-script its args