Posso pós-formatar tamanhos de tabulação de coluna para que o espaçamento seja o menor denominador comum no Linux?

Você pode usar column -t your_file(mas não obtém o bit justificado certo, até onde eu sei)

Saídas:

drwxr-xr-x  755  4   boss  boss  4096   2021-10-29  22:49:12  .
drwxr-xr-x  755  4   boss  boss  4096   2021-10-29  22:49:12  .
drwxr-xr-x  755  36  boss  boss  4096   2021-11-01  11:30:24  ..
-rw-r--r--  644  1   boss  boss  97708  2021-11-01  11:30:16  .custom
-rw-r--r--  644  1   boss  boss  4013   2021-10-11  22:04:04  .custom-dk

Em relação a "ou sed" em sua pergunta - sed é a ferramenta certa para usar para transformações simples s/old/new/ em strings individuais, o que você está fazendo não é nada disso e, portanto, sed não deve ser uma opção para considerar.

Usando uma abordagem de 2 passos, primeiro para determinar a largura e o alinhamento máximos para cada coluna e depois usá-los ao imprimir, usando qualquer awk em qualquer shell em cada caixa Unix:

$ cat tst.awk
BEGIN { FS="\t" }
NR==FNR {
    for (i=1; i<=NF; i++) {
        align[i] = ( $i ~ /^[0-9]+$/ ? "" : "-" )
        width[i] = ( length($i) > width[i] ? length($i) : width[i] )
    }
    next
}
{
    for (i=1; i<NF; i++) {
        printf "%" align[i] width[i] "s ", $i
    }
    print $NF
}

$ awk -f tst.awk file file
drwxr-xr-x 755  4 boss boss  4096 2021-10-29 22:49:12 .
drwxr-xr-x 755  4 boss boss  4096 2021-10-29 22:49:12 .
drwxr-xr-x 755 36 boss boss  4096 2021-11-01 11:30:24 ..
-rw-r--r-- 644  1 boss boss 97708 2021-11-01 11:30:16 .custom
-rw-r--r-- 644  1 boss boss  4013 2021-10-11 22:04:04 .custom-dk

O acima assume que sua última coluna deve ser sempre alinhada à esquerda, se esse não for o caso, avise-nos, pois não é difícil de lidar de qualquer maneira. Também assume que o alinhamento de uma coluna pode ser determinado pelos valores (numéricos ou não) nos campos na última linha de entrada.

Se a entrada tiver que vir de um pipe em vez de um arquivo (e, portanto, você não pode abrir a entrada duas vezes), você poderá armazenar a entrada em um array e imprimir isso na seção END:

$ cat tst.awk
BEGIN { FS = "\t" }
{
    for (i=1; i<=NF; i++) {
        width[i] = ( length($i) > width[i] ? length($i) : width[i] )
        align[i] = ( $i ~ /^[0-9]+$/ ? "" : "-" )
        vals[NR,i] = $i
    }
}
END {
    for (n=1; n<=NR; n++) {
        for (i=1; i<NF; i++) {
            printf "%" align[i] width[i] "s ", vals[n,i]
        }
        print vals[n,NF]
    }
}

e depois chame como:

$ stat --printf="%A\t%a\t%h\t%U\t%G\t%s\t%.19y\t%n\n" . .* | awk -f tst.awk