Início / unix / Perguntas / 565811
Accepted
atapaka
Asked: 2020-02-05 14:57:18 +0800 CST

awk inicia a impressão com base em uma condição

  • 772

Eu tenho dados de teste em um arquivotext.txt

a
b
test
test2
1,2
3,3

Eu quero gerar o arquivo a partir do número da linha em que test é + 2. Eu preciso que isso seja um oneliner utilizável em gnuplot, cheguei ao seguinte:

awk -v linestart=$(awk '$0~"test" {a=NR}END{print a+2}' $filename) 'BEGIN{FS=",";OFS="\t";lines}NR>=linestart{print $1, $2}' $filename

mas eu preciso de alguma forma fornecer o conteúdo do arquivo para dois awkque não sei como fazer. Então eu vim com a solução com o $filenamemas isso tem o problema, como entrar $filename.

Eu estava pensando na linha:

echo "test.txt" | read filename | awk -v linestart=$(awk '$0~"test" {a=NR}END{print a+2}' $filename) 'BEGIN{FS=",";OFS="\t";lines}NR>=linestart{print $1, $2}' $filename

mas isso não funciona.

De que outra forma posso fazer o trabalho acima? O problema óbvio é que eu preciso saber o número da linha onde quero começar a imprimir antes de executar awk. eu também estava pensando em algo sobre isso:

awk 'BEGIN{FS=",";OFS="\t";lines=100000}{if ($0~"test"){lines=NR+2}; if(NR>=lines){print $1, $2}}'

Mas eu nem tentei pois, é muito feio e não geral, tenho que fazer a variável linessempre suficientemente grande. Então, existe uma solução elegante que funcionaria com um pipe de arquivo de texto normal ou, no outro caso, com alguma maneira de inserir o nome do arquivo?

bash awk

4 respostas

  1. Best Answer

    Usando ed:

    $ printf '%s\n' '/^test/+2,$p' | ed -s file
1,2
3,3

    No ededitor, o comando /^test/+2,$pimprimiria ( p) as linhas de duas linhas além da linha correspondente ^test, até o final ( $).

    Usando awk:

    $ awk '/^test/ { flag = 1; count = 1 }; (flag == 1 && count <= 0); { count-- }' file
1,2
3,3

    Aqui, uma linha será impressa se flagfor 1 e se countfor menor ou igual a zero. O sinalizador é definido como 1 quando o padrão ^testé correspondido nos dados de entrada e counttambém é definido para o número de linhas a serem ignoradas até que a saída deva iniciar (sem contar a linha atual). O counté diminuído para todas as linhas.

    Uma abordagem um pouco diferente com awk:

    $ awk '/^test/ { getline; while (getline > 0) print }' file
1,2
3,3

    Aqui, combinamos nosso padrão e imediatamente lemos e descartamos a próxima linha de entrada. Em seguida, usamos um loop while para ler o restante do arquivo, imprimindo cada linha lida.

    Exatamente a mesma abordagem, mas com sed:

    $ sed -n -e '/^test/ { n' -e ':again' -e 'n; p; b again' -e '}' file
1,2
3,3

    Combine o padrão, então leia e descarte a próxima linha ( n), então entre em um loop lendo e imprimindo cada linha ( n; p;). O loop é composto pelo rótulo againe a ramificação/salto para este rótulo ( b again).

    • 6

  2. Se você sabe que seus dados começam 2 linhas depois testde , e não há mais linhas testneles, você pode se safar com algo assim:

    awk '/^test$/ { f=1 } f && f++ > 2' filename

    Além disso, para enviar esses dados para o Gnuplot, você pode considerar fazê-lo através de um pipe como este:

    (
echo "set datafile separator ','"
echo "plot '-' using 1:2 with lines"
awk '/^test$/ { f=1 } f && f++ > 2' filename
echo "e"
) | gnuplot -persist

    Plotagem dos dados

    • 2

  3. Você pode fazer isso trivialmente com um start, endintervalo com uma condição final que é sempre falsa e uma condição inicial que pula linhas:

    awk '/test/ && getline && getline, 0'
    • 0 
  4. $ awk '/test/{n=NR} n && NR>n' file
1,2
3,3

$ awk '/test/{n=NR+1} n && NR>n' file
3,3

    Veja também https://stackoverflow.com/a/17914105/1745001

    • 0

relate perguntas