Início / unix / Perguntas / 542230
Accepted
Stefan van den Akker
Asked: 2019-09-18 04:21:49 +0800 CST

intervalo de endereços sed regexp menos (ou mais) o número de linhas

  • 772

Eu tenho vários arquivos ICS que contêm algo como:

...
PRIORITY:4
DESCRIPTION:this
  was
  a
  triumph
COMPLETED:20180101T160000
...

Estou interessado em abordar a DESCRIPTIONchave. A chave DESCRIPTIONpode ocorrer em qualquer lugar no arquivo ICS. Nem sempre é seguido pela chave COMPLETED.

Usando ed, eu faria assim:

/DESCRIPTION/;/^[^ ]/-1p

o que resulta em:

DESCRIPTION:this
  was
  a
  triumph

No entanto, sednão parece ter essa capacidade:

sed -n '/DESCRIPTION/,/^[^ ]/-1p' filename

resulta em

sed: -e expressão #1, char 22: comando desconhecido: `-'

Existe uma maneira de fazer o que eu quero usando sed?

Resolvendo este problema específico

Este problema pode ser resolvido por:

sed -n '/DESCRIPTION:/,/^\S/ { /\(DESCRIPTION\|^\s\)/p }' example.ics

Mas isso parece muito pesado e verboso.

awktambém parece não suportar /begpat/,/endpat/-1, então você terminaria com algo como:

BEGIN { endpat = "^(DESCRIPTION|\\s)" }
/^DESCRIPTION/, $0 !~ endpat {
    if ($0 ~ endpat) {print}
}
sed

2 respostas

  1. Best Answer

    Você estava bem perto:

    sed '/DESCRIPTION/p;//,/^[^ ]/!d;//d' filename

    Faria o que você quiser. Por quê?

    • Você pode definir um intervalo e descartar tudo fora desse intervalo com/start/,/stop/!d
    • Então você deseja excluir a última linha da correspondência também. Um seguinte //dfaria isso (o padrão vazio //corresponde ao último padrão, portanto, a /stop/linha)
    • Mas, no seu caso, esse padrão também corresponde à primeira linha. Má sorte! Então vamos print-lo antes e você obtém o comando que eu mostrei (novamente usando o padrão vazio)

    Atualização com diferentes abordagens

    Em seu comentário, você chamou isso de "solução alternativa", o que é de algum ponto de vista. E, na verdade, para mim, eu escolheria uma sedabordagem diferente e mais ish:

    sed '/^ /{H;d;};x;/^DESCRIPTION/!d' filename

    Isso deve parecer natural para os sedamantes, mas talvez estranho à primeira vista para alguns. Segue a abordagem do " desejo-que-poderia-lembrar ". O que é aquilo? Cada vez que você chega a uma linha sem recuo, você pensa "Eu gostaria de poder lembrar as linhas anteriores, se elas valem a pena ser impressas". Então simplesmente assumimos que os temos em nossa memória, o espaço de espera, para que possamos simplesmente xalterar o espaço de padrão e manter o espaço e dexcluí-lo se não começar com DESCRIPTION(se começar com, será impresso por padrão).

    O bom xé que cada linha não recuada estará no espaço de espera automaticamente, então só precisamos adicionar as linhas recuadas ao espaço de espera com H. Isso o que a /^ /{H;d;}peça faz ( dé evitar saída ou processamento adicional para essas linhas).

    Agora, o oposto é o que um programador faria. Eles provavelmente fariam um loop assim:

    sed '/DESCRIPTION/!d
  :loop
  N;/\n[^ ].*/!bloop
s///' filename

    Ou seja, largue tudo até encontrarmos a palavra- DESCRIPTIONchave, então inicie um loop para coletar linhas Ne faça um loop até que haja uma linha com um non-space \n[^ ].*. Nesse caso, remova essa última linha (mais uma vez aproveitando o padrão vazio).

    Isso também funciona, mas essa não é a maneira típica de fazer as coisas no sed.

    • 4

  2. Sim, o sed suporta intervalos de endereços como este:

    sed -n '/string1/,/string2/p file

    No seu caso, tente usar -Ea opção para expressões regulares estendidas.

    sed -nE '/this/,/^[^ ]/p' filename
    • 0

relate perguntas