zsh: É possível implementar uma `exportação local`?

As variáveis ​​estão sempre disponíveis para os subprocessos. Dentro:

a=1
(echo "$a")

você vê 1.

Acho que o que você quis dizer é que você quer que a variável tenha um escopo local e seja exportada para o ambiente para que sejam passadas como variáveis ​​de ambiente para comandos que são executados . A execução de um comando é o que limpa a memória de um processo (e o ambiente é uma forma de preservar alguns dados nele), bifurcando um filho copia toda a memória para que tudo seja preservado.

Para isso, você pode usar local -x:

a=(1 2)
f() {
  local -x a=3
  typeset -p a
  printenv a # printenv being *executed*
}
f
typeset -p a

dá:

typeset -x a=3
3
typeset -a a=( 1 2 )

Ou você pode exportdepois de ter sido declarado local:

a=(1 2)
f() {
  local a=3
  export a
  typeset -p a
  printenv a # printenv being *executed*
}
f
typeset -p a

Observe que você pode passar uma variável no ambiente de um único comando sem defini-la de outra forma como uma variável do shell com:

a=(1 2)
f() {
  a=3 printenv a # printenv being *executed*
}
f
typeset -p a

Observe que localse originou no shell Almquist no final dos anos 80, mas funciona de maneira diferente do zsh's. No shell Almquist (e seus descendentes como dash e o sh do NetBSD/FreeBSD), localafeta apenas o escopo de uma variável e não altera o valor ou os atributos de uma variável.

O zsh localfunciona mais como o ksh93, typesetpois declara uma nova variável que é independente daquela no escopo externo.

ksh88, bash e pdksh's local/ typesettentam fazer isso também, mas ainda herdam alguns atributos da variável do escopo externo, incluindo o atributo export . Isso mudou no ksh93, mas observe que o ksh93 também mudou para escopo estático e implementa apenas o escopo local em funções declaradas com a function f { ...; }sintaxe.

Assumindo que o que você quer fazer é dar a um processo uma variável de ambiente com um valor que pode ser diferente do valor da variável shell com o mesmo nome que pode estar no escopo do shell no ponto de invocação do comando:

a () {
    YACY_TIMEOUT=60 yacy -r -d std
}

Essa é a sintaxe padrão para executar um comando e fornecer a ele um valor específico de uma variável de ambiente. A variável YACY_TIMEOUT, se existir no mesmo escopo que o corpo da afunção, não será modificada.

Isso funcionaria em qualquer shell POSIX.

O que isso não faz é permitir que você use YACY_TIMEOUTcom o valor "local" dentro da função antes de chamar yacy.

Em zshou em qualquer outro shell que suporte variáveis ​​locais declaradas com local, você pode fazer

a () {
    local YACY_TIMEOUT=60

    YACY_TIMEOUT=$YACY_TIMEOUT yacy -r -d sth
}

Aqui, YACY_TIMEOUTseria local para a afunção. A injeção da variável como variável de ambiente no yacyprocesso acontece como no primeiro exemplo que dei, precedendo a invocação por uma atribuição.

Agora YACY_TIMEOUTé local e também está disponível no yacyambiente do processo. Isso funcionaria em qualquer shell que suporte o uso localpara declarar variáveis ​​locais.

Use um subshell:

function a() (
 export YACY_TIMEOUT=60
 yacy -r -d sth
)

Exemplo:

% a () ( TIMEOUT=60; env | grep TIMEOUT )
% export TIMEOUT=4
% echo $TIMEOUT
4
% a
TIMEOUT=60
% echo $TIMEOUT
4