Início / unix / Perguntas / 507768
Accepted
villapx
Asked: 2019-03-22 09:03:37 +0800 CST

awk atribuir a várias variáveis ​​de uma só vez

  • 772

Estou tentando extrair dois valores numéricos de uma string e atribuí-los a variáveis ​​usando awk( gawké o que estou usando especificamente). Eu quero puxar os números de versão principal e secundária de uma string de versão do tmux em awkvariáveis, por exemplo:

  • entrada: tmux 2.8; maj == 2emin == 8
  • entrada: tmux 1.9a; maj == 1emin == 9
  • entrada: tmux 2.10; maj == 2emin == 10

Supondo que minha entrada venha de tmux -Vstdin, atualmente tenho o seguinte:

tmux -V | awk '{
                  maj = +gensub(/([0-9]+)\..*/, "\\1", "g", $2);
                  min = +gensub(/.*\.([0-9]+).*/, "\\1", "g", $2);
                  # ...do something with maj and min...
               }'

Isso funciona, mas como muitos usuários do tmux sabem, usar if-shellno .tmux.confarquivo (onde espero usar essas coisas) pode facilmente levar a linhas muito longas no arquivo de configuração, então estou querendo saber se há uma maneira de combinar essas duas variáveis atribuições em uma instrução para economizar espaço... ou qualquer outra maneira de coletar essas duas variáveis ​​da entrada e economizar espaço.

Estou pensando em algo como:

awk '{ maj, min = +gensub(/([0-9]+)\.([0-9]+).*/, "\\1 \\2", "g", $2); }'

... como em Python, mas essa sintaxe em particular não existe em awk. Existe alguma outra coisa que é possível?

Observe que a legibilidade não é realmente uma preocupação, apenas o comprimento.

awk gawk

4 respostas

  1. Como você está usando o GNU awk, você pode usar a forma de 3 argumentos de match()para armazenar vários grupos de captura:

    awk '
    match($0, /([0-9]+)\.([0-9]+)/, m) {maj=m[1]; min=m[2]; print maj, min}
' <<END
tmux 2.8
tmux 1.9a
tmux 2.10
END

    2 8
1 9
2 10

    https://www.gnu.org/software/gawk/manual/html_node/String-Functions.html

    • 12
  2. Best Answer

    Observe que gensubé uma gawkextensão, não funcionará com nenhuma outra awkimplementação. Observe também que o +operador unário não força a conversão numérica em todas as awkimplementações, usando + 0é mais portátil.

    Aqui você poderia fazer:

    tmux -V | awk -F '[ .]' '{maj = $2+0; min = $3+0; print maj, min}'

    Se você não se importa em usar awkextensões GNU, você também pode fazer:

    tmux -V | awk -v FPAT='[0-9]+' '{maj = $1; min = $2; print maj, min}'
    • 9

  3. Você pode dividir a versão em uma matriz:

    awk '{ split($2, ver, /[.a-z]/) }'

    então use ver[1]em vez de maj, ver[2]em vez de min.

    Adicionar a-zao separador remove qualquer letra minúscula do número da versão. (As outras soluções são melhores aqui, pois extraem números explicitamente.)

    • 5

  4. Outro usuário postou esta resposta e depois foi excluída. Achei útil:

    Usando a split()função, divida a string da versão em um array ver, então acesse ver[1]e ver[2]em vez de maje min, respectivamente (ou simplesmente armazene os valores nessas variáveis):

    tmux -V | awk '{ split($2, ver, /[.a-z]/); print ver[1], ver[2] }'

    A vantagem aqui é que split()não é uma gawkextensão (embora seu quarto argumento opcional sepsseja).

    • 3

relate perguntas