Início / unix / Perguntas / 504082
Accepted
mrjayviper
Asked: 2019-03-04 03:03:24 +0800 CST

zsh: Como obter o valor da variável com base em outra variável?

  • 772

Acho que um exemplo explicaria melhor o que eu preciso

_v1="windows"

_v2_windows="/mnt/d"
_v2_osx="/Volumes/d"

echo $_v2_`echo $_v1`

Eu quero ecoar o valor de _v2_windowsmas usando _v1para determinar qual dos dois v2s obter.

Eu sei que pode usar uma casedeclaração para resolver o problema, mas estou tentando evitar isso.

zsh variable

2 respostas

  1. Best Answer

    Com zsh:

    • ${(P)varname}expande para o valor da variável cujo nome está armazenado em $varname. Portanto, se $varnamecontém var, ${(P)varname}expande para a mesma coisa que $var.
    • ${(e)var}expande para o conteúdo de, $varmas também executa expansões de parâmetros, substituição de comandos e expansão aritmética dentro. Portanto, se $varcontém $othervar, ${(e)var}expande para a mesma coisa que $othervar.
    • Você pode aninhar operadores de expansão de variáveis, então coisas como ${(P)${var:-something}}trabalho
    • ${:-content}é uma maneira de ter uma expansão de parâmetro expandida para texto arbitrário (aqui content)

    (veja o manual para detalhes)

    Então você poderia fazer:

    _v1=windows
_v2_windows=/mnt/d
printf '%s\n' ${(P)${:-_v2_$_v1}}

    Ou:

    printf '%s\n' ${(e)${:-\$_v2_$_v1}}

    Ou faça isso em duas etapas:

    varname=_v2_$_v1
printf '%s\n' ${(P)varname}

    Ou:

    expansions_to_evaluate=\$_v2_$_v1

printf '%s\n' ${(e)expansions_to_evaluate}

    Ou você pode usar a sintaxe POSIX padrão:

    eval 'printf "%s\n" "${_v2_'"$_v1"'}"'

    Esteja ciente de que, se o valor de $_v1não estiver sob seu controle, tudo isso equivale a uma vulnerabilidade de injeção de comando arbitrária, você precisa primeiro limpar o valor.

    Observe também que zshsuporta arrays associativos (e tem muito antes bashde ), então você pode fazer:

    typeset -A mnt
mnt=(
  windows /mnt/d
  osx     /Volumes/d
)
os=windows
printf '%s\n' $mnt[$os]

    O que seria muito mais legível e não teria nenhuma dessas implicações de segurança.

    • 10 
  2. printf '%s\n' "${(P)$(echo "_v2_$_v1")}"

    alternativamente

    var=_v2_$_v1
printf '%s\n' "${(P)var}"

    Em ambos os casos, o sinalizador de expansão de parâmetro (P)é usado para expandir o nome dentro ${...}do nome da variável real da qual gostaríamos de obter o valor.

    Isso é semelhante à indireção variável ${!...}no bashshell.

    • 2

relate perguntas