Início / unix / Perguntas / 494889
Accepted
Nick ODell
Asked: 2019-01-17 09:18:43 +0800 CST

Faça awk produzir erro em não numérico

  • 772

Eu tenho um programa que soma uma coluna em um arquivo:

awk -v col=2 '{sum+=$col}END{print sum}' input-file

No entanto, ele tem um problema: se você fornecer um arquivo que não possui dados numéricos (ou se um número estiver faltando), ele o interpretará como zero.

Eu quero que ele produza um erro se um dos campos não puder ser analisado como um número.

Aqui está um exemplo de entrada:

bob 1
dave 2
alice 3.5
foo bar

Eu quero que ele produza um erro porque 'bar' não é um número, em vez de ignorar o erro.

awk numeric-data

4 respostas

  1. Uma maneira razoável de testar seria comparar o campo usando testes semelhantes a strtod, que é o método que o awk usa para converter strings em números:

    $2 !~ / *[+-]?[[:digit:]]/ { print "NAN: " $2; exit 1; }

    O acima difere de strtod, pois não considera INFINITY ou NAN como "números". O requisito de espaço à esquerda pode ser relaxado sob o comportamento de divisão de campo padrão do awk - o que significa que os campos nunca conteriam espaço à esquerda:

    $2 !~ /[+-]?[[:digit:]]/ { print "NAN: " $2; exit 1; }

    Um refinamento adicional, graças ao comentário e resposta de Stéphane aqui :

    $2 !~ /^[+-]?([[:digit:]]*\.?[[:digit:]]*([eE][-+]?[[:digit:]]+)?|0[xX][[:xdigit:]]*\.?[[:xdigit:]]*([pP][-+]?[[:digit:]]+)?)$/ { print "NAN: " $2; exit 1; }

    Dividido para uma legibilidade um pouco melhor, esse regex é:

    /^[+-]?([[:digit:]]*\.?[[:digit:]]*([eE][-+]?[[:digit:]]+)?|\
        0[xX][[:xdigit:]]*\.?[[:xdigit:]]*([pP][-+]?[[:digit:]]+)?)$/

    ... onde a intenção é permitir um possível + ou - à esquerda, então um número de ponto flutuante ou um número hexadecimal. O número de ponto flutuante tem dígitos iniciais opcionais, um separador de opção (aqui fixado para ser um ponto .), seguido por algum número de dígitos, opcionalmente seguido por um expoente. O número hexadecimal deve começar com 0xou 0X, seguido por dígitos hexadecimais, um separador, mais dígitos hexadecimais e, opcionalmente, seguido por uma "potência" (expoente). Todo o segundo campo deve corresponder a um desses formatos (conforme ancorado por ^e $). Omitidas aqui, para fins desta pergunta, estão as opções NAN e INFINITY.

    Outra opção seria forçar uma conversão numérica, depois compará-la com zero e depois comparar a entrada original com algo que converteria em zero; mais especificamente, ele começa com um + ou - opcional, então é seguido por zeros ou seguido por um ponto e zeros:

    { number=0 + $2;
  if (!number && $2 !~ /^[+-]?(0+)|\.0+/)
    print "NAN: "$2;
}
    • 7
  2. Best Answer

    Acabei com isso:

    awk -v col=$col '
typeof($col) != "strnum" {
    print "Error on line " NR ": " $col " is not numeric"
    noprint=1
    exit 1
}
{
    sum+=$col
}
END {
    if(!noprint)
        print sum
}' $file

    Isso usa typeof, que é uma extensão GNU awk. typeof($col)retorna 'strnum' se $colfor um número válido e 'string' ou 'unassigned' se não for.

    Consulte Posso determinar o tipo de uma variável awk?

    • 5 
  3. awk -v col=2 '
    $col+0==0 && $col!~/^[+-]?0/ { print "bad number " $col > "/dev/stderr" } 
    {sum+=$col}
    END{print sum}' input-file

    Cabe a você complicá-lo se quiser que ele também trate .0ou .0e+33como representações válidas de 0; observe que awkignorará o lixo à direita ao converter strings em números ( "1.4e1e3"+0, "1.4e1.e7"+0ou "14+13"+0serão todos iguais a 14).

    • 2

  4. Se você fornecer um arquivo que não possui dados numéricos,

    $col ~ /[^-.[:digit:]]/ {print "Error, non-numeric :"; print $col; exit 1};

    Explicação basta usar um RegEx para verificar a presença de caracteres que não são dígitos nem ponto flutuante, sinal, etc.

    (ou se faltar um número)

    adicionar

    || ($col == "")

    ou

    || (length($col) == 0)

    à regra.

    Ou você pode usar uma comparação NFse for a última coluna, como no seu exemplo.

    • 1

relate perguntas