Argumento de linha de comando no awk

Os argumentos fornecidos no final da linha de comando awksão geralmente considerados como nomes de arquivos dos quais o awkscript será lido. Para definir uma variável na linha de comando, use -v variable=value, por exemplo

awk -v num=10 -f script.awk

Isso permitiria que você usasse numcomo uma variável em seu script. O valor inicial da variável será 10 no exemplo acima.

Você também pode ler variáveis ​​de ambiente usando ENVIRON["variable"]em seu script (para alguma variável de ambiente chamada variable), ou olhar para os argumentos da linha de comando ARGV[n]onde né algum inteiro positivo.

Com $1in awk, você faria referência ao valor do primeiro campo no registro atual, mas como você o está usando em um BEGINbloco, nenhum dado foi lido de nenhum arquivo.

O número em seu código está sendo interpretado como zero, pois é uma variável vazia usada em um contexto aritmético.

$1não é o primeiro argumento da linha de comando, mas o primeiro campo após a divisão da linha FS(e será a string vazia em BEGIN, já que nenhuma linha foi dividida ainda).

Os argumentos da linha de comando estão na matriz ARGV:

$ awk 'BEGIN { for(i = 1; i < ARGC; i++) print ARGV[i] }' 1st 2nd 3rd
1st
2nd
3rd

ARGV[0]é sempre o nome do interpretador ( awkou gawk, etc).

Para permitir awkignorar um argumento de linha de comando e não tentar abri-lo mais tarde como um arquivo, você deve excluí-lo ou configurá-lo para a string vazia: por exemplo. ARGV[1]="".

Como uma nota lateral, qualquer argumento do formulário var=valuetambém será interpretado como uma atribuição de variável por awk, e será avaliado após o processamento dos argumentos do arquivo que o precedem:

$ echo yes > file
$ awk '{ gsub(/e/, var); print }' var=1 file var=2 file var=3 file
y1s
y2s
y3s

Para usar um nome de arquivo real do formulário key=valcom awk, você deve passá-lo como um caminho relativo ou absoluto, por exemplo. awk '{...}' ./key=val.

Como já foi apontado, nenhuma entrada está sendo lida na seção BEGIN. Você pode fazer seu código executar conforme o esperado, se você verificar a primeira linha de entrada e fornecer o número em stdin:

echo 10 | awk 'NR==1{
num=$1;
if (num%2==0)
printf "%d is Even number.\n",num;
else printf "%d is odd Number.\n",num
}'
10 is Even number.

O Awk regular não tem problemas para processar argumentos de linha de comando como qualquer outro programa semelhante a C faria, sem recorrer a qualquer gawkcomportamento específico do GNU, pipes ou redirecionamento ( <), ou a -vopção (atribuição de variável).

O manuseio de argumentos de entrada ARGC(o argumento count , um inteiro) e ARGV(o argumento vetor , outra palavra para "lista") são abordados em detalhes no manual .

Mosvy fez um ótimo trabalho explicando o histórico e resumindo o que precisa ser feito para analisar arquivos ARGV. Aqui está o seu objetivo original, implementado como um script de shell autônomo, testado no macOS e no GNU/Linux.

simple_if.awk

#!/usr/bin/awk -f
##
##  simple_if - tell user if a number given as an argument is even or odd
##
##  Example:    ./simple_if.awk 11
##
BEGIN {
    num = ARGV[1];

    # if you expect to arguments AND read from one or more input files, you need
    # to remove the arguments from ARGV so Awk doesn't attempt to open them as
    # files (causing an error)
    #ARGV[1] = "";

    if (num % 2 == 0) {
        printf "%d is an even number.\n", num;
    } else {
        printf "%d is an odd number.\n", num;
    }
}

Faça um script Awk como este executável com chmod a+x scriptname.awk, coloque-o em seu $PATH, e ele pode ser executado como qualquer outro script Bash, Python, Perl, programa C, o que for.

Se awkexistir em algum outro lugar do seu sistema, atualize a #!linha apropriadamente; pode não ser possível usar /usr/bin/envporque awk deve ter a -fopção de rodar seu script, e… é complicado .

A .awkextensão não é necessária , mas pode ajudar seu editor a habilitar o realce de sintaxe adequado. Deixe-o desligado e ninguém precisa saber que é um script Awk.

Aqui está um exemplo mais completo que faz algo útil e tem um tratamento de erros razoável:

simple_stats.awk

#!/usr/bin/awk -f
##
##  simple_stats - do simple 1-variable statistics (min/max/sum/average) on
##                 the first column of its input file(s)
##
##  examples:      ./simple_stats min numbers.txt
##                 ./simple_stats all numbers.txt    # all stats
##                 ./simple_stats sum <(du MyFiles)  # Bash proc. substitution
##
##                 # specify '-' as the filename when reading from stdin
##                 seq 1 100 | ./simple_stats avg -
##
BEGIN {
    # expect stats operation as the first argument
    op = ARGV[1]

    # unset this array index so Awk doesn't try opening it as a file later
    # ref: https://www.gnu.org/software/gawk/manual/html_node/ARGC-and-ARGV.html
    ARGV[1] = ""  

    # if you wanted to process multiple command line arguments here, you could
    # loop over ARGV, using something like
    # for (i=0; i<ARGC; i++) { if (ARGV[i] == "...") { ... } }

    if (op !~ /^(min|max|sum|avg|all)$/) {
        print "ERROR: Expected one of min/max/sum/avg/all." >"/dev/stderr"
        # 'exit' in BEGIN will always run the EXIT block, if one exists
        # see https://www.gnu.org/software/gawk/manual/html_node/Assert-Function.html
        _assert_exit = 1
        exit 1
    }

    # ordinarily Awk reads stdin without specifying; here, '-' seems necessary
    if (ARGV[2] == "") {
        print "ERROR: Need an input file (or '-' for stdin)." >"/dev/stderr"
        _assert_exit = 1
        exit 1
    }
}

# 'min' needs an initial value so take the first record
NR == 1 { min = $1 }

# for every input line (including the first)...
{
    sum += $1
    if ($1 > max) max = $1
    if ($1 < min) min = $1
}

END {
    if (_assert_exit) exit 1;  # if 'exit' was pending from BEGIN block

    if (op == "min" || op == "all")
        printf "The minimum is: %15d\n", min
    if (op == "max" || op == "all")
        printf "The maximum is: %15d\n", max
    if (op == "sum" || op == "all")
        printf "The sum is:     %15d\n", sum
    if (op == "avg" || op == "all")
        printf "The average is: %15.2f\n", sum/NR
}