Início / unix / Perguntas / 470262
Accepted
Siva
Asked: 2018-09-21 04:15:02 +0800 CST

combinando vários arquivos pela primeira coluna

  • 772

Eu tenho mais de cinquenta arquivos com um nome distinto em um diretório. Por exemplo:

Arquivo1:

Type,A,
RR,1,
CD,2,

Arquivo2:

Type,B,
CD,2,
FG,3,

Arquivo3:

Type,C,
RR,5,
FG,8,
QR,9,

Saída desejada

Type,A,B,C,
CD,2,2,,
FG,,3,8,
QR,,,9,
RR,1,,5

Eu tentei com joine pastemas sem sorte... Alguma sugestão?

rhel awk

2 respostas

  1. Best Answer

    Aqui estão alguns awk GNU bastante complicados. GNU awk ( gawk) necessário para arrays-of-arrays

    gawk -F, '
    NR  == 1 {n=1; header[n] = $1}
    FNR == 1 {n++; header[n] = $2; next}

    !($1 in data) {data[$1][1] = $1}
    {data[$1][n] = $2}

    # from https://www.gnu.org/software/gawk/manual/html_node/Join-Function.html
    function join(array, start, end, sep,    result, i)
    {
        if (sep == "")
            sep = " "
        else if (sep == SUBSEP) # magic value
            sep = ""
        result = array[start]
        for (i = start + 1; i <= end; i++)
            result = result sep array[i]
        return result
    }

    END {
        print join(header, 1, n, FS)
        PROCINFO["sorted_in"] = "@ind_str_asc"   # for sorted output
        for (type in data)
            print join(data[type], 1, n, FS)
    }
' file{1,2,3}

    Type,A,B,C
CD,2,2,
FG,,3,8
QR,,,9
RR,1,,5

    Estou assumindo que cada arquivo tem 2 colunas, então não é completamente genérico.

    Uma versão que não depende do GNU awk (testado com mawk)

    mawk -F, '
    NR  == 1 {n=1; header[n] = $1}
    FNR == 1 {n++; header[n] = $2; next}
    {key[$1]; data[$1,n] = $2}
    END {
        for (i=1; i<=n; i++)
            printf "%s%s", header[i], (i==n ? ORS : FS)
        for (type in key) {
            printf "%s%s", type, FS
            for (i=2; i<=n; i++)
                printf "%s%s", data[type,i], (i==n ? ORS : FS)
        }
    }
' file{1,2,3}
    • 0

  2. Isso não é particularmente difícil de fazer, mesmo sem matrizes multidimensionais reais:

    /Type/ { type=$2; types[$2] = 1 }
!/Type/ { data[type,$1] = $2; keys[$1] = 1 }
END {
    m = asorti(types)
    value = "Type"
    for (i = 1; i <= m; i++) {
        value = value "," types[i];
    }
    print value;
    n = asorti(keys)
    for (i = 1; i <= n; i++) {
        value=keys[i]
        for (k = 1; k <= m; k++) {
            value = value "," data[types[k],keys[i]]
        }
        print value;
    }
}

    No entanto, você ainda precisa do GNU awkpara as funções de classificação.

    • 0

relate perguntas