Início / unix / Perguntas / 468002
Accepted
don_crissti
Asked: 2018-09-11 03:10:23 +0800 CST

Maneira portátil de remover a primeira linha do espaço de padrão (quando várias linhas estão presentes)

  • 772

Qual é a maneira portátil de excluir a primeira linha 1 do espaço do padrão?
Com gnu sedeu posso fazer

s/[^\n]*\n//

mas até onde eu sei isso (usando \nem uma expressão de colchetes []) não é portátil.

Exemplo prático: aqui, sedimprime a última seção do arquivo incluindo o delimitador via código portátil. Eu gostaria de remover a primeira linha do espaço do padrão para excluir o delimitador e fazer isso de maneira portátil. Com gnu sedé simples:

sed 'H;/===/h;$!d;//d;x;s/[^\n]*\n//' infile

1: Obviamente isso deve ser feito sem reiniciar o ciclo de comandos...

sed

3 respostas

  1. Eu não tenho um sed adequado para tentar, mas você sempre pode fazer loops internos testando e removendo caracteres até chegar à nova linha:

    sed 'H
/===/h
$!d
//d
x
{
   :rpt
   s/^\n//
   t done
   s/.//
   t rpt
}
:done
'

    A segunda ramificação de teste, t rpt, precisa ser a tem vez de a bpara redefinir o sinalizador interno que diz que an sfoi bem-sucedido desde a última leitura. Você não precisa do {}, eles são apenas para mostrar melhor o loop.

    • 2
  2. Best Answer

    Uma maneira de fazer esse tipo de coisa portátil é a seguinte:

    sed -e '
   # ... assuming prev sed cmds made pattern space carry newline(s)
   y/\n_/_\n/     ;# exchange newlines with an underscore
   s/^[^_]*_//    ;# remove up till the first underscore, ummm newline
   y/\n_/_\n/     ;# revert the transformation
'
    • 2

  3. Bobo, mas funcionando:

    sed 'h;G;s/\n/&&/;s/^\(.*\)\n\(.*\)\n\1\2$/\2/'

    O que é isso? Você dobra todo o conteúdo e, em seguida, substitui a primeira nova linha por duas novas linhas. Então você tem o mesmo conteúdo duas vezes, com uma nova linha adicional após a primeira linha. Com referências anteriores, agora você pode identificar as diferentes partes.

    Se você não quiser usar o buffer de retenção:

    sed 's/.*/&&/;s/\n/&&/;s/^\(.*\)\n\(.*\)\1\2$/\2/'

    E não, eu não gosto disso. Se houver uma maneira de evitá-lo, evite-o.

    • 1

relate perguntas