Como sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;' funciona para imprimir parágrafo [duplicado]

O comando

sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;' file

imprime parágrafos que contêm a string AAA.

Isso invoca sedcom o seguinte sedscript:

/./{
    H
    $!d
}
x
/AAA/!d

Versão anotada:

/./{        # When hitting a line that contains at least one character...
    H;      # Append the line to the "hold space".
    $!d;    # If it's not the last line, delete it.
}
x;          # Swap the hold space and the pattern space.
/AAA/!d;    # Delete the pattern space if it does not contain the string "AAA"
            # (implicit print)

Assim, em suma, ele coleta linha após linha no "espaço de retenção" (um buffer de uso geral em sed) e, quando encontra uma linha vazia (o /./padrão não corresponde), determina se a coleção de linhas armazenada contém a string AAAe imprime, se isso acontecer.

Isso também é descrito em uma resposta aqui: GREP / SED ou AWK: imprima o parágrafo inteiro em um arquivo na correspondência de padrão

Dado o arquivo

this is
a paragraph

this is
another one

this paragraph
contains the string
AAA

Seria a saída do último parágrafo (com uma linha vazia à esquerda).

Para se livrar da linha vazia que precederá cada parágrafo de saída (se é isso que você deseja), use

/./{
    H
    $!d
}
x
/AAA/!d
s/\n//

Ou, na linha de comando

sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;s/\n//'