Início / unix / Perguntas / 433273
Accepted
maddingl
Asked: 2018-03-25 07:15:04 +0800 CST

Alterando o estilo do cursor com base no modo em zsh e vim

  • 772

Eu uso o modo vi em oh-my-zsh com o tema af-magic .

Quero que o estilo do cursor indique se estou no modo normal (bloco) ou no modo de inserção (feixe), tanto em zshquanto em vim.

Isto é o que eu tenho até agora:

No meu ~/.zshrc:

    # vim mode config
    # ---------------

    # Activate vim mode.
    bindkey -v

    # Remove mode switching delay.
    KEYTIMEOUT=5

    # Change cursor shape for different vi modes.
    function zle-keymap-select {
      if [[ ${KEYMAP} == vicmd ]] ||
         [[ $1 = 'block' ]]; then
        echo -ne '\e[1 q'

      elif [[ ${KEYMAP} == main ]] ||
           [[ ${KEYMAP} == viins ]] ||
           [[ ${KEYMAP} = '' ]] ||
           [[ $1 = 'beam' ]]; then
        echo -ne '\e[5 q'
      fi
    }
    zle -N zle-keymap-select

    # Use beam shape cursor on startup.
    echo -ne '\e[5 q'

    # Use beam shape cursor for each new prompt.
    preexec() {
       echo -ne '\e[5 q'
    }

Conforme encontrado aqui .

Em vim, eu uso Vundle e terminus .

Com essas configurações, ambos funcionam zshcomo vimdeveriam quando considerados de forma independente. No entanto, quando entro no modo vimde inserção , inicia no modo normal (como deveria), mas ainda mostra o cursor da forma do feixe. Da mesma forma, quando saio , volto para o modo de inserção , mas o cursor ainda está em forma de bloco (já que o último modo era normal ).zshvimvimzshvim

Depois disso, quando alterno os modos pela primeira vez (em ambos zshe vim), o cursor se comporta da maneira que deveria novamente.

Como posso fazê-los exibir o cursor correto depois de entrar e sair vimtambém?

eu tentei colocar

    autocmd VimEnter * stopinsert
    autocmd VimLeave * startinsert

em my ~.vimrc, mas isso não afeta o cursor.

zsh vim

6 respostas

  1. Best Answer

    Acho melhor usar ao precmd()invés de preexec():

    # .zshrc

_fix_cursor() {
   echo -ne '\e[5 q'
}

precmd_functions+=(_fix_cursor)

    Deste jeito:

    • você não tem que mudar.vimrc
    • cursor também é fixo quando você cria um novo prompt sem executar um comando
    • você não precisa escrever echo -ne '\e[5 q'duas vezes em seu arquivo .zshrc.
    • 18

  2. Isso funciona perfeitamente para mim, foi retirado daqui: https://gist.github.com/LukeSmithxyz/e62f26e55ea8b0ed41a65912fbebbe52

    # vi mode
bindkey -v
export KEYTIMEOUT=1

# Change cursor shape for different vi modes.
function zle-keymap-select {
  if [[ ${KEYMAP} == vicmd ]] ||
     [[ $1 = 'block' ]]; then
    echo -ne '\e[1 q'
  elif [[ ${KEYMAP} == main ]] ||
       [[ ${KEYMAP} == viins ]] ||
       [[ ${KEYMAP} = '' ]] ||
       [[ $1 = 'beam' ]]; then
    echo -ne '\e[5 q'
  fi
}
zle -N zle-keymap-select
zle-line-init() {
    zle -K viins # initiate `vi insert` as keymap (can be removed if `bindkey -V` has been set elsewhere)
    echo -ne "\e[5 q"
}
zle -N zle-line-init
echo -ne '\e[5 q' # Use beam shape cursor on startup.
preexec() { echo -ne '\e[5 q' ;} # Use beam shape cursor for each new prompt.

    Você pode personalizar o tipo de cursor que deseja (piscando ou não, |, retângulo ou _) alterando os números nas seguintes sequências \e[5 q(5 é para feixe, 1 é para bloco) da seguinte forma:

    Set cursor style (DECSCUSR), VT520.
0  ⇒  blinking block.
1  ⇒  blinking block (default).
2  ⇒  steady block.
3  ⇒  blinking underline.
4  ⇒  steady underline.
5  ⇒  blinking bar, xterm.
6  ⇒  steady bar, xterm.
    • 6

  3. Basta adicionar a linha:

    export VI_MODE_SET_CURSOR=true

    ao seu ~/.zshrc. É mencionado na discussão da edição #9570 .

    • 3

  4. Eu encontrei uma solução:

    Eu coloquei isso no meu ~/.vimrc:

    autocmd VimEnter * silent exec "! echo -ne '\e[1 q'"
autocmd VimLeave * silent exec "! echo -ne '\e[5 q'"
    • 2

  5. Você também pode usarzle-line-init()

    zle-line-init() {
    zle -K viins # initiate `vi insert` as keymap (can be removed if `bindkey -V` has been set elsewhere)
    echo -ne "\e[5 q"
}

    Acho que esse problema é melhor resolvido usando isso, em vez de precmd()ou preexec()como ambos devem ser usados ​​para executar comandos, em vez de corrigir o prompt.

    • 0

  6. O script a seguir funciona para mim. Ele muda o cursor toda vez após iniciar/sair de um programa.

    function _set_cursor() {
    if [[ $TMUX = '' ]]; then
      echo -ne $1
    else
      echo -ne "\ePtmux;\e\e$1\e\\"
    fi
}

# Remove mode switching delay.
KEYTIMEOUT=5

function _set_block_cursor() { _set_cursor '\e[2 q' }
function _set_beam_cursor() { _set_cursor '\e[0 q' }

function zle-keymap-select {
  if [[ ${KEYMAP} == vicmd ]] || [[ $1 = 'block' ]]; then
      _set_block_cursor
  else
      _set_beam_cursor
  fi
}
zle -N zle-keymap-select
# ensure beam cursor when starting new terminal
precmd_functions+=(_set_beam_cursor) #
# ensure insert mode and beam cursor when exiting vim
zle-line-init() { zle -K viins; _set_beam_cursor }
zle-line-finish() { _set_block_cursor }
zle -N zle-line-finish
    • 0

relate perguntas