Início / unix / Perguntas / 411304
Accepted
bdesham
Asked: 2017-12-17 11:48:20 +0800 CST

Como faço para verificar se uma matriz zsh contém um determinado valor?

  • 772

Suponha que eu tenha um array não associativo que foi definido como

my_array=(foo bar baz)

Como posso verificar se o array contém uma determinada string? Prefiro uma solução que possa ser usada dentro da condicional de um ifbloco (por exemplo if contains $my_array "something"; then ...).

zsh

2 respostas

  1. Best Answer
    array=(foo bar baz foo)
pattern=f*
value=foo

if (($array[(I)$pattern])); then
  echo array contains at least one value that matches the pattern
fi

if (($array[(Ie)$value])); then
  echo value is amongst the values of the array
fi

    $array[(I)foo]retorna o índice da última ocorrência de fooin $arraye 0 se não for encontrado. O esinalizador é para que seja uma ecorrespondência exata em vez de uma correspondência de padrão.

    Para verificar $valuese está em uma lista literal de valores, você pode passar essa lista de valores para uma função anônima e procurar o $valuein $@no corpo da função:

    if ()(( $@[(Ie)$value] )) foo bar baz and some more; then
  echo "It's one of those"
fi

    Para saber quantas vezes o valor é encontrado no array, você pode usar o ${A:*B}operador (elementos do array Aque também estão no array B):

    array=(foo bar baz foo)
value=foo
search=("$value")
(){print -r $# occurrence${2+s} of $value in array} "${(@)array:*search}"

    Ou usando correspondência de padrões nos elementos da matriz:

    (){print -r $# occurrence${2+s} of $value in array} "${(M@)array:#$value}"
    • 37

  2. Se você tem um array $my_arraye quer saber se ele contém a string foo, um teste possível é

    [[ ${my_array[(ie)foo]} -le ${#my_array} ]]

    O valor completo e exato do elemento da matriz deve ser foo; não é uma verificação de substring ou algo assim.

    Se você quiser ver se o valor da variável $my_stringestá na matriz, use

    [[ ${my_array[(ie)$my_string]} -le ${#my_array} ]]

    Essa (ie)sintaxe não é muito óbvia. É explicado na seção Subscript Flags do manual do ZSH. A iparte significa que estamos usando “subscrito reverso”: ao invés de passar um subscrito e obter um valor, como fazemos com o usual ${my_array[1]}, estamos passando um valor e pedindo o primeiro subscrito que daria esse valor. Esse subscrito é numérico e baseado em 1 (o primeiro elemento da matriz está no índice 1), o que é diferente da convenção usada pela maioria das linguagens de programação. O ein (ie)significa que queremos uma correspondência exata, sem expandir caracteres de correspondência de padrão como *.

    Se o valor não for encontrado na matriz, ${my_array[(ie)foo]será avaliado como o primeiro índice após o final da matriz, portanto, para uma matriz de 3 elementos, retornará 4. ${#my_array}fornece o índice do último elemento da matriz; portanto, se o primeiro é menor ou igual ao último, então o valor fornecido está presente na matriz em algum lugar. Se você quiser verificar se um determinado valor não está na matriz, altere o “menor que ou igual a” para “maior que”:

    [[ ${my_array[(ie)foo]} -gt ${#my_array} ]]
    • 28

relate perguntas