Início / dba / Perguntas / 62130
Accepted
Peter PitLock
Asked: 2014-03-31 23:58:47 +0800 CST

Dentro do procedimento armazenado, defina os nomes das colunas da consulta retornada de acordo com a variável

  • 772

Eu tenho uma consulta que gostaria de reutilizar, em vez de ter muitas cópias diferentes dela apenas para alterar o nome da coluna.

O relatório (por exemplo ) usa a mesma consulta, mas há cães ou gatos na tabela e, se houver gatos, ele retornará 'Nr of Cats' e, se houver cães, 'Nr of Dogs' como título para a tabela retornada.

declare @Animals table (
  AnimalType varchar(20), Name varchar(20)
  )

insert into @Animals(Type, Name) values('Cat', 'Garfield')

declare @AnimalType varchar(20)

set @AnimalType = (Select Top 1  AnimalType from @Animals )

select 
    Case when @AnimalType = 'Cat' 
           then 'Nr of Cats' 
           else 'Nr of Dogs' = count(*)  from @Animals
sql-server-2005 temporary-tables

1 respostas

  1. Best Answer

    Você precisará usar o SQL dinâmico para isso, se realmente quiser que o SQL Server transmita os resultados com nomes de colunas variáveis.

    A título de exemplo, considere o seguinte:

    Use tempdb para evitar surpresas desagradáveis ​​em objetos existentes:

    USE tempdb;

    Crie uma tabela para armazenar os dados de amostra. Como estamos usando SQL dinâmico, não podemos usar uma variável de tabela para isso.

    IF OBJECT_ID('dbo.Animals') IS NOT NULL
DROP TABLE dbo.Animals;

CREATE TABLE dbo.Animals 
(
    AnimalType varchar(20) NOT NULL
    , AnimalName varchar(20) NOT NULL
);

INSERT INTO dbo.Animals (AnimalType, AnimalName)
VALUES ('Cat', 'Garfield')
    , ('Dog', 'Lucy');

GO

    Crie um procedimento armazenado usando T-SQL dinâmico:

    IF OBJECT_ID('dbo.DynamicResults') IS NOT NULL
DROP PROCEDURE dbo.DynamicResults;
GO
CREATE PROCEDURE dbo.DynamicResults
(
    @DogsOrCats varchar(3)
)
AS
BEGIN
    SET NOCOUNT ON;
    DECLARE @msg nvarchar(1000);
    IF (@DogsOrCats = 'Dog' OR @DogsOrCats = 'Cat')
    BEGIN
        DECLARE @cmd nvarchar(max);
        DECLARE @vars nvarchar(max);
        SET @vars = '@Type varchar(20)';
        SET @cmd = 'SELECT a.AnimalType
            , [NumberOf' + @DogsOrCats + 's] = COUNT(1)
        FROM dbo.Animals a
        WHERE a.AnimalType = @Type
        GROUP BY a.AnimalType;';
        EXEC sys.sp_executesql @cmd, @vars, @Type = @DogsOrCats;
    END
    ELSE
    BEGIN
        SET @msg = '@DogsOrCats must be either ''Dog'' or ''Cat''';
        RAISERROR (@msg, 14, 1) WITH NOWAIT;
    END
END
GO

    A execução do procedimento armazenado retorna vários conjuntos de resultados, com base no valor passado como@DogsOrCats

    EXEC dbo.DynamicResults 'Cat';

    Retorna:

    +------------+--------------+
| AnimalType | NumberOfCats |
+------------+--------------+
| Gato | 1 |
+------------+--------------+

    EXEC dbo.DynamicResults 'Dog';

    Retorna:

    +------------+--------------+
| AnimalType | NumberOfDogs |
+------------+--------------+
| Cão | 1 |
+------------+--------------+
    • 3

relate perguntas