Início / dba / Perguntas / 5863
Accepted
Delux
Asked: 2011-09-17 06:59:57 +0800 CST

Anexar gatilho de banco de dados

  • 772

É possível escrever um gatilho quando alguém faz uma alteração no nível do servidor, como anexar ou criar um banco de dados? Tenho um servidor de desenvolvimento onde qualquer pessoa pode adicionar uma cópia do banco de dados do produto para teste, mas não há procedimento de limpeza. Desejo adicionar as seguintes propriedades estendidas quando um banco de dados é adicionado.

EXEC sys.sp_addextendedproperty 
@name = N'Owner', 
@value = N'Username';

EXEC sys.sp_addextendedproperty 
@name = N'StartDate', 
@value = N'9/1/2011';
sql-server-2008

1 respostas

  1. Best Answer

    Você pode usar gatilhos DDL para isso. Não parece haver um evento DDL gerado para anexar, mas definitivamente existe para CREATE DATABASE. Você poderia contornar isso negando direitos para sp_attachdb e forçar todos a usar CREATE DATABASE FOR ATTACH.

    O exemplo a seguir parece um hack, então esperamos que alguém com mais experiência em gatilhos DDL proponha uma maneira mais organizada de fazer isso.

    IF EXISTS (SELECT NULL FROM sys.server_triggers WHERE name = 'ddl_trig_database')
BEGIN
    DROP TRIGGER ddl_trig_database
    ON ALL SERVER;
END
GO

CREATE TRIGGER ddl_trig_database 
ON ALL SERVER 
FOR CREATE_DATABASE 
AS 
    DECLARE 
        @DatabaseName NVARCHAR(128)
        , @CreatedBy NVARCHAR(128)
        , @CreatedDate NVARCHAR(23)
        , @SQL NVARCHAR(4000);

    SELECT 
        @DatabaseName = EVENTDATA().value('(/EVENT_INSTANCE/DatabaseName)[1]','NVARCHAR(128)')
        , @CreatedBy = EVENTDATA().value('(/EVENT_INSTANCE/LoginName)[1]','NVARCHAR(128)')
        , @CreatedDate = EVENTDATA().value('(/EVENT_INSTANCE/PostTime)[1]','NVARCHAR(23)');

    SET @SQL = '
        USE ' + @DatabaseName + ';
        EXEC sys.sp_addextendedproperty @name = N''Owner'', @value = N''' + @CreatedBy + ''';
        EXEC sys.sp_addextendedproperty @name = N''StartDate'', @value = N''' + @CreatedDate + ''';';

    -- PRINT @SQL;
    EXEC (@SQL);

GO

CREATE DATABASE MyTestDatabase;
GO

DROP TRIGGER ddl_trig_database
ON ALL SERVER;
GO

DROP DATABASE MyTestDatabase;
GO
    • 4

relate perguntas