Início / dba / Perguntas / 50986
Accepted
RThomas
Asked: 2013-10-04 18:44:40 +0800 CST

Fazer uma restauração pontual com o CDC ativado; Possível?

  • 772

Descobri esta semana, da maneira mais difícil, que as opções NORECOVERYde restauração do banco de dados KEEP_CDCsão mutuamente exclusivas . Então, isso levanta a questão. Como você faz uma restauração de banco de dados, mantendo o CDC intacto, com backups completos e de log?

Fazendo pesquisas no MSDN, etc. Não consigo encontrar nenhuma documentação sobre como restaurar um banco de dados KEEP_CDCusando qualquer outra opção além de uma única restauração completa do banco de dados com RECOVERYespecificação.

Consegui encontrar uma tentativa que fez os logs completos e subseqüentes sem a keep_cdcopção de esperar até o log final. Só então a tabela foi colocada online com a opção RECOVERYe KEEP_CDC. O resultado foi um esquema CDC corrompido , conforme demonstrado aqui.

Se a intenção é KEEP_CDCrestaurar, você está realmente limitado apenas a um backup completo ou existe um mecanismo semelhante à tentativa acima para mantê-lo intacto durante restaurações de vários arquivos em um servidor diferente do original?

sql-server sql-server-2008

1 respostas

  1. Best Answer

    O Change Data Capture, ou CDC, não requer a palavra- KEEP_CDCchave ao restaurar um banco de dados para o servidor original . Ao restaurar um banco de dados para um servidor diferente do servidor original, você pode usar a KEEP_CDCpalavra-chave para especificar que os dados de captura de dados alterados sejam retidos no banco de dados. Isso é intencional e está claramente declarado no BOL aqui na seção intitulada "Restaurando ou anexando um banco de dados habilitado para captura de dados alterados"

    Este código mostra o CDC em ação antes e depois de umRESTORE DATABASE ... WITH NORECOVERY

    CREATE DATABASE CDC_RESTORE_TEST 
ON (NAME='CDC_RESTORE_TEST', FILENAME = 'C:\SQLServer\Data\CDC_RESTORE_TEST.mdf', SIZE = 10MB, FILEGROWTH = 1MB)
LOG ON (NAME = 'CDC_RESTORE_TEST_LOG', FILENAME = 'C:\SQLServer\Logs\CDC_RESTORE_TEST.ldf', SIZE = 1MB, FILEGROWTH = 1MB);
GO
ALTER DATABASE CDC_RESTORE_TEST
SET RECOVERY FULL;
GO
USE CDC_RESTORE_TEST;
GO
EXEC sys.sp_cdc_enable_db;
GO
CREATE TABLE Test
( 
    ID INT NOT NULL CONSTRAINT PK_Test PRIMARY KEY CLUSTERED IDENTITY(1,1)
    , DATA NVARCHAR(255) NOT NULL
);
EXEC sys.sp_cdc_enable_table 'dbo', 'Test', 'dbo_Test', 1, NULL;
GO
ALTER TABLE Test ADD Data1 NVARCHAR(255) NOT NULL;
WAITFOR DELAY '00:00:15'; /* wait for event to be captured */
EXEC sys.sp_cdc_get_ddl_history 'dbo_Test';

USE Master;
GO
BACKUP DATABASE CDC_RESTORE_TEST TO DISK='C:\SQLServer\CDC_RESTORE_TEST.BAK';
BACKUP LOG CDC_RESTORE_TEST TO DISK='C:\SQLServer\CDC_RESTORE_TEST_LOG.BAK';
GO
ALTER DATABASE CDC_RESTORE_TEST SET SINGLE_USER WITH ROLLBACK IMMEDIATE;
GO
DROP DATABASE CDC_RESTORE_TEST;
GO
RESTORE DATABASE CDC_RESTORE_TEST FROM DISK='C:\SQLServer\CDC_RESTORE_TEST.bak'
WITH NORECOVERY;
RESTORE LOG CDC_RESTORE_TEST FROM DISK='C:\SQLServer\CDC_RESTORE_TEST_LOG.bak'
WITH RECOVERY;
GO
USE CDC_RESTORE_TEST;
GO
EXEC sys.sp_cdc_get_ddl_history 'dbo_Test';

    A restauração do mesmo backup no mesmo servidor como um novo nome de banco de dados parece manter o CDC:

    USE Master;
GO
RESTORE DATABASE CDC_RESTORE_TEST1 FROM DISK='C:\SQLServer\CDC_RESTORE_TEST.bak' 
WITH NORECOVERY
    , MOVE 'CDC_RESTORE_TEST' TO 'C:\SQLServer\Data\CDC_Restore_test1.mdf'
    , MOVE 'CDC_RESTORE_TEST_LOG' TO 'C:\SQLServer\Logs\CDC_Restore_test1.ldf';
RESTORE LOG CDC_RESTORE_TEST1 FROM DISK='C:\SQLServer\CDC_RESTORE_TEST_LOG.bak'
WITH RECOVERY
    , MOVE 'CDC_RESTORE_TEST' TO 'C:\SQLServer\Data\CDC_Restore_test1.mdf'
    , MOVE 'CDC_RESTORE_TEST_LOG' TO 'C:\SQLServer\Logs\CDC_Restore_test1.ldf';
GO
USE CDC_RESTORE_TEST;
GO
EXEC sys.sp_cdc_get_ddl_history 'dbo_Test';
    • 1

relate perguntas