Propriedades XML de pesquisa de texto completo

Se você tiver, digamos, um documento do Word ou do Excel, eles terão propriedades conhecidas do documento , como Autor, Título, Palavras-chave, etc., que você pode associar a uma lista de propriedades de pesquisa e, em seguida, a um índice de texto completo. Propriedades disponíveis dependendo de seu IFilter. Você pode usar a palavra-chave PROPERTY para consultar essas propriedades.

No entanto, com um arquivo .xml, é improvável que o documento tenha essas propriedades personalizadas e o que você realmente deseja fazer é pesquisar o conteúdo xml. AccountNo soa como apenas um atributo no xml em vez de uma propriedade de documento. Você pode pesquisar seu xml usando métodos comuns de pesquisa de texto completo; no entanto, a marcação xml e os nomes de atributos são ignorados em índices de texto completo. Você pode consultar o atributo e o conteúdo do elemento. Você também pode converter o conteúdo do arquivo para xml e usar os métodos xml integrados, por exemplo, .query, .nodes, .value e .exist. Trabalhe com esta demonstração e veja se faz sentido:

USE master
GO

IF EXISTS ( SELECT * FROM sys.databases WHERE name = 'filestreamDemo' )
BEGIN
    ALTER DATABASE filestreamDemo SET SINGLE_USER WITH ROLLBACK IMMEDIATE
    DROP DATABASE filestreamDemo
END
GO

CREATE DATABASE filestreamDemo
ON PRIMARY (name = filestreamDemo_File, filename = N'c:\temp\filestreamDemo.mdf' ),
FILEGROUP FG_filestreamDemo CONTAINS FILESTREAM ( NAME = filestreamDemo_FS_File, FILENAME = N'c:\temp\filestreamDemo_FS' )
WITH FILESTREAM ( 
    non_transacted_access = FULL,
    directory_name = N'filestreamDemo' )
GO


USE filestreamDemo
GO

-- DROP TABLE dbo.AuditTable
IF OBJECT_ID('dbo.AuditTable') IS NULL 
CREATE TABLE dbo.AuditTable
(
    rowId           INT IDENTITY CONSTRAINT PK_AuditTable PRIMARY KEY,
    Id              UNIQUEIDENTIFIER ROWGUIDCOL NOT NULL UNIQUE,
    [message]       VARBINARY(MAX) FILESTREAM NULL,
    fileExt         VARCHAR(5) NOT NULL
)
GO

IF NOT EXISTS ( SELECT * FROM sys.fulltext_catalogs WHERE name = N'ft' ) 
CREATE FULLTEXT CATALOG ft AS DEFAULT
GO

CREATE FULLTEXT INDEX ON dbo.AuditTable
    ( [message] TYPE COLUMN fileExt )
    KEY INDEX PK_AuditTable ON ft
    WITH ( CHANGE_TRACKING = MANUAL, STOPLIST = SYSTEM )
GO

INSERT INTO dbo.AuditTable ( Id, [message], fileExt )
SELECT
    NEWID(),
    CAST( '<root AccountNo="123456"/>' AS VARBINARY(MAX) ),
    'xml'

UNION ALL

SELECT
    NEWID(),
    CAST( '<root><child AccountNo="123456"/>elementValue</root>' AS VARBINARY(MAX) ),
    'xml'

UNION ALL

SELECT
    NEWID(),
    CAST( '<dummy/>' AS VARBINARY(MAX) ),
    'xml'
GO


ALTER FULLTEXT INDEX ON dbo.AuditTable START FULL POPULATION;
GO

SELECT 'before' ft, * FROM sys.fulltext_indexes
GO

DECLARE @i INT = 0

WHILE EXISTS ( SELECT * FROM sys.fulltext_indexes WHERE has_crawl_completed = 0 )
BEGIN
    WAITFOR DELAY '00:00:05'

    SET @i += 1
    IF @i > 60 BEGIN THROW 50001, 'Too many loops!', 1 BREAK END

END
GO

SELECT 'after' ft, * FROM sys.fulltext_indexes
GO


-- Have a look in the full-text index
SELECT *
FROM sys.dm_fts_index_keywords_by_document(DB_ID(), OBJECT_ID('dbo.AuditTable'))
ORDER BY document_id


-- Search using full-text; WON'T WORK
SELECT [message], CAST( [message] AS VARCHAR(MAX) ) 
FROM AuditTable
WHERE CONTAINS ( [message], 'AccountNo');


-- will work
SELECT [message], CAST( [message] AS VARCHAR(MAX) ) 
FROM AuditTable
WHERE CONTAINS ( [message], '123456');


-- will work: numbers are prefixed with nn in full-text indexes
SELECT [message], CAST( [message] AS VARCHAR(MAX) ) 
FROM AuditTable
WHERE CONTAINS ( [message], 'nn123456');


-- Cast to xml and search using normal xml methods
SELECT *
FROM ( SELECT rowId, ID, CAST( [message] AS XML ) [message] FROM dbo.AuditTable ) a
WHERE a.message.exist('//@AccountNo[.="123456"]') = 1
GO

Também fiz um teste e não consegui um documento xml para emitir nenhuma propriedade, conforme sugerido pela documentação. No entanto, eu poderia fazer isso funcionar com um documento padrão do Word.