Como alterar a ordem de disparo dos Triggers?

Você pode usar a instrução a seguir para listar todos os gatilhos em cada tabela.

EXEC sp_MSForEachTable 'PRINT ''?'' 
EXEC sp_helptrigger ''?'''

Depois de descobrir todos os gatilhos. Você pode alterar manualmente a ordem usando sp_settriggerorder

IIRC você não pode garantir exatamente a ordem que os gatilhos (com a mesma definição do que reagir e quando) disparam para uma determinada ação contra uma tabela, para qualquer número de gatilhos.

Você pode pensar se houver três ou menos, pois pode usar sp_settriggerorder para definir o primeiro como o primeiro, o último como o último e o do meio para ter uma ordem "indefinida".

Se seus gatilhos são sensíveis à ordem que são executados, isso geralmente indica que seu design está ficando mais complexo do que o necessário (geralmente devido ao crescimento orgânico) e pode se beneficiar de alguma refatoração.

-- List tables with triggers and their firing order.  By Jackson Jarvis.
SELECT [tbl].[name] AS 'Table'
      ,[trg].[name] AS 'Trigger'
      ,CASE OBJECTPROPERTY([trg].[id] ,'ExecIsFirstInsertTrigger')
            WHEN 0 THEN ''
            ELSE 'X'
       END AS 'Insert First'
      ,CASE OBJECTPROPERTY([trg].[id] ,'ExecIsLastInsertTrigger')
            WHEN 0 THEN ''
            ELSE 'X'
       END AS 'Insert Last'
      ,CASE OBJECTPROPERTY([trg].[id] ,'ExecIsFirstUpdateTrigger')
            WHEN 0 THEN ''
            ELSE 'X'
       END AS 'Update First'
      ,CASE OBJECTPROPERTY([trg].[id] ,'ExecIsLastUpdateTrigger')
            WHEN 0 THEN ''
            ELSE 'X'
       END AS 'Update Last'
      ,CASE OBJECTPROPERTY([trg].[id] ,'ExecIsFirstDeleteTrigger')
            WHEN 0 THEN ''
            ELSE 'X'
       END AS 'Delete First'
      ,CASE OBJECTPROPERTY([trg].[id] ,'ExecIsLastDeleteTrigger')
            WHEN 0 THEN ''
            ELSE 'X'
       END AS 'Delete Last'
  FROM            [sysobjects] AS [trg] WITH (NOLOCK)
       INNER JOIN [sysobjects] AS [tbl] WITH (NOLOCK)
            ON  [trg].[parent_obj] = [tbl].[id]
  WHERE [trg].[TYPE] IN (N'TR')
  ORDER BY
       [tbl].[name] ASC
      ,[trg].[name] ASC
  ;